สอบถามการดึงข้อมูลตารางต้นทางมาแสดงยังปลายทางโดยมีข้อมูล Column ไม่เท่ากันค่ะ

[Jitladda.kh]

จากไฟล์งาน จะมีแผ่นงาน อยู่ 2 แผ่นงาน
คือ ดิฉันต้องการดึงข้อมูลจากแผ่นงาน ชื่อ " Meter " ไปใส่ที่แผ่นงานชื่อ "ยอดขาย ณ ตรวจ"

โดยอยากให้จาก แผ่นงานชื่อ "Meter" โดยข้อมูลเริ่มจาก คอลั้ม A วิ่งไป A (ไฮไลท์สีเหลือง)
, คอลั้ม B วิ่งไป B (ไฮไลท์สีเหลือง) , คอลั้ม D วิ่งไป C (ไฮไลท์ฟ้า) ,คอลั้ม L วิ่งไป F (ไฮไลท์สีเขียว)

และข้อมูลจาก แผ่นงาน Meter ที่วิ่งไป จะมีข้อมูลคอลั้มไม่เท่ากับ แผ่นงาน "ยอดขาย ณ ตรวจ"
ดิฉันจะสามารถดึงข้อมูลไปใส่ได้อย่างไรค่ะ โดยเงื่อนไข อยากให้ข้อมูลชื่อผลิตภัณฑ์ และหัวจ่ายที่ วิ่งไปให้ถูกช่องในตารางปลายทางนะค่ะ

ข้อมูลตารางน้ำมัน.xls

[snasui]

ตัวอย่างสูตรตามด้านล่างครับ

1. V8, U10, V10, W10 คีย์ข้อความ Last Row, Min, List และ Max ตามลำดับ เพื่อเป็นข้อความอธิบายรายการของคอลัมน์ช่วย
2. ที่ U11 คีย์
   =11*(ROWS(U$11:U11)-1)+1
   Enter > Copy ลงด้านล่าง
3. ที่ V11 คีย์
   =INDEX(Meter!$B$7:$B$41,SMALL(IF(FREQUENCY(IF(Meter!$B$7:$B$41<>"",MATCH(Meter!$B$7:$B$41,Meter!$B$7:$B$41,0)),ROW(Meter!$B$7:$B$41)-ROW(Meter!$B$7)+1),ROW(Meter!$B$7:$B$41)-ROW(Meter!$B$7)+1),ROWS(V$11:V11)))
   Ctrl+Shift+Enter > Copy ลงด้านล่าง
4. ที่ W11 คีย์
   =U11+COUNTIF(Meter!$B$7:$B$41,V11)-1
   Enter > Copy ลงด้านล่าง
5. ที่ V9 คีย์
   =LOOKUP(2,1/(V11:V21<>""),W11:W21)
   Enter
6. ที่ B11 คีย์
   =IF(ROWS(B$11:B11)>$V$9,"",LOOKUP(CHAR(255),CHOOSE({1,2},"",LOOKUP(2,1/(ROWS(B$11:B11)>=$U$11:$U$21)/(ROWS(B$11:B11)<=$W$11:$W$21),$V$11:$V$21))))
   Enter > Copy ลงด้านล่างล่างยังเซลล์ที่เกี่ยวข้อง
7. ที่ A11 คีย์
   =IF($B11="","",INDEX(Meter!A$7:A$40,MATCH($B11,Meter!$B$7:$B$40,0)+COUNTIF($B$11:$B11,$B11)-1))
   Enter > Copy ลงด้านล่างล่างยังเซลล์ที่เกี่ยวข้อง > คัดลอกสูตรไปใช้กับคอลัมน์อื่น ๆ โดยเปลี่ยนเฉพาะข้อความที่ระบายสี

!

Note: Ctrl+Shift+Enter เป็นการสร้างสูตร Array โดยสามารถเลือกดำเนินการตามข้อ 1 หรือ 2 ด้านล่าง กรณีคีย์สูตรเอง เมื่อคีย์สูตรแล้ว แทนที่จะกด Enter ให้กดแป้น Ctrl และ Shift พร้อมกันค้างไว้แล้วกด Enter เพื่อสร้างเป็นสูตร Array กรณี Copy สูตรไปวางให้กดแป้น F2 เพื่อทำการ Edit Cell นั้นก่อน จากนั้นกดแป้น Ctrl และ Shift พร้อมกันค้างไว้แล้วตามด้วย Enter เพื่อสร้างเป็นสูตร Array หากกดแป้นถูกต้องสูตรนั้นจะมีเครื่องหมายปีกกาครอบ เช่น {=YourFormulas(...)} ปีกกานี้ไม่สามารถคีย์เข้าไปเอง จะต้องมาด้วยการกดแป้น Ctrl+Shift+Enter เท่านั้น ถ้ายังไม่เห็นปีกกาครอบสูตรแสดงว่ากดแป้นให้รับสูตรไม่ถูกต้อง การแก้ไขเปลี่ยนแปลงสูตร Array จะต้องกดแป้นให้รับสูตรด้วย Ctrl+Shift+Enter ทุกครั้ง

[Jitladda.kh]

ขอบคุณมาก จะลองไปใช้นะค่ะ

[Jitladda.kh]

Paper Audit-2020-1.xls

อาจารย์ค่ะ ขอเพิ่มเติม

ถ้าในกรณีช่อง ผลิตภัณฑ์ บางสาขาไม่มีเลย ข้อมูลที่วิ่งไปมันไปแทนที่ตัวตารางที่ไม่มีข้อมูล แบบนี้มีสูตรช่วยได้ไหม
อยากเช่นแนบตัวอย่างมา ข้อมูลของ B20 ไม่มี ทำให้ข้อมูลของ B10 วิ่งไปแทนที่ช่องตารางนั้น รบกวนช่วยหน่อยนะค่ะ
ขอบคุณมากค่ะ

[snasui]

อ่านแล้วไม่เข้าใจกรุณาอธิบายมาใหม่ครับ

ชี้ให้เห็นว่าข้อมูลเป็นแบบไหน คำตอบปัจจุบันเป็นแบบไหน ต้องการคำตอบเป็นอย่างไร จะได้สะดวกในการทำความเข้าใจครับ