ยินดีต้อนรับสู่กระดานถามตอบ Excel and VBA และอื่น ๆ ที่เป็นมิตรกับทุกท่าน มีไฟล์แนบมหาศาล ช่วยให้ท่านค้นหาและติดตามศึกษาได้โดยง่าย ระบุ Version ของ Excel
ฟอรัมถาม-ตอบปัญหาการใช้งานสูตรและฟังก์ชัน Excel
Forum rules
ไม่อนุญาตให้ใช้ภาษาแชทในการถามและตอบปัญหา ไม่ใช้คำว่า "คับ" หรือ "อ่ะครับ" แทนคำว่า "ครับ" ไม่ใช้คำว่า "เด๋ว" แทนคำว่า "เดี๋ยว" เป็นต้น เนื่องจากเมื่อแปลเป็นภาษาต่างประเทศแล้วจะให้ความหมายผิดไปจากที่ควรจะเป็น ห้ามถามโดยระบุชื่อผู้ตอบและต้องตั้งชื่อกระทู้ให้สื่อถึงปัญหาที่จะถาม ไม่ตั้งชื่อว่า ช่วยด้วยครับ, มีปัญหามาปรึกษาครับ เป็นต้น กรุณาอธิบายปัญหาและระบุคำตอบที่ต้องการมาในกระทู้ด้วยเสมอถึงแม้จะอธิบายไว้ในไฟล์แนบแล้วก็ตาม ทั้งนี้เพื่ออำนวยความสะดวกแก่เพื่อนสมาชิกในการค้นหาข้อมูล กรุณาแนบไฟล์ตัวอย่างพร้อมแสดงคำตอบที่ถูกต้องมาในไฟล์ด้วยเพื่อให้ง่ายต่อการทำความเข้าใจและสะดวกต่อการตอบคำถาม (ขนาดไฟล์ไม่เกิน 500Kb ขนาดภาพไม่เกิน 800*600 Pixel) ไม่แนบเป็น Link มาจากแหล่งอื่นที่อาจจะถูกลบทิ้งไปโดยต้นทางในภายหลัง นอกจากนี้ไม่ควรแนบไฟล์ที่มีข้อมูลสำคัญอันก่อให้เกิดความเสียหายกับตนเองและผู้อื่น กรณีเป็นคำถามเกี่ยวกับ Programming เช่น VBA, VB.Net, C#, SQL ฯลฯ ต้องลองเขียนมาเองก่อนเสมอ ถามเฉพาะที่ติดปัญหา ระบุ Module, Procedure ที่ติดปัญหาให้ชัดเจน กรุณาโพสต์ Code ให้แสดงเป็น Code คือเปิดด้วย [code] และปิดด้วย [/code] ตัวอย่างเช่น [code]dim r as range[/code] เพื่อให้แตกต่างจากข้อความทั่วไป สะดวกในการอ่านและทดสอบ (คลิกเพื่อดูตัวอย่าง) กรุณาแจ้งผลการใช้งานเมื่อได้รับคำตอบว่าตรงกับความต้องการหรือไม่
ILoveExcel
Member
Posts: 69 Joined: Fri Jul 07, 2017 1:54 pmExcel Ver: 365
#1
Post
by ILoveExcel Wed Jun 17, 2020 11:13 am
สวัสดีครับอาจารย์
You do not have the required permissions to view the files attached to this post.
puriwutpokin
Guru
Posts: 3801 Joined: Fri Jan 04, 2013 9:49 pmLocation: BangkokExcel Ver: MS.365
#2
Post
by puriwutpokin Wed Jun 17, 2020 11:24 am
ที่ E2=IFERROR(AGGREGATE(15,6,A$2:A$12/(FREQUENCY(MATCH(A$2:A$12,A$2:A$12,0),ROW(A$2:A$12)-ROW(A$1))>0),ROWS(E$2:E2)),"")
ILoveExcel
Member
Posts: 69 Joined: Fri Jul 07, 2017 1:54 pmExcel Ver: 365
#3
Post
by ILoveExcel Wed Jun 17, 2020 11:48 am
puriwutpokin wrote: Wed Jun 17, 2020 11:24 am
ที่ E2=IFERROR(AGGREGATE(15,6,A$2:A$12/(FREQUENCY(MATCH(A$2:A$12,A$2:A$12,0),ROW(A$2:A$12)-ROW(A$1))>0),ROWS(E$2:E2)),"")
ที่ F2=COUNTIF(A$2:A$12,E2)
ที่ G2=SUMIF(A$2:A$12,E2,B$2:B$12)
ทั้งหมดคัดลอกลงครับ
ขอบคุณครับ ผมทดลองเปลี่ยนรหัสแล้วแต่สูตรไม่คำนวณผลลัพธ์ให้ครับ ตามไฟล์แนบมาครับ
You do not have the required permissions to view the files attached to this post.
puriwutpokin
Guru
Posts: 3801 Joined: Fri Jan 04, 2013 9:49 pmLocation: BangkokExcel Ver: MS.365
#4
Post
by puriwutpokin Wed Jun 17, 2020 12:27 pm
ปรับที่ E2=IFERROR(AGGREGATE(15,6,A$2:A$12/(FREQUENCY(IF(A$2:A$12>0,MATCH(A$2:A$12,A$2:A$12,0)),ROW(A$2:A$12)-ROW(A$1))>0),ROWS(E$2:E2)),"") กด Ctrl+Shift+Enter
ILoveExcel
Member
Posts: 69 Joined: Fri Jul 07, 2017 1:54 pmExcel Ver: 365
#5
Post
by ILoveExcel Wed Jun 17, 2020 12:55 pm
puriwutpokin wrote: Wed Jun 17, 2020 12:27 pm
ปรับที่ E2=IFERROR(AGGREGATE(15,6,A$2:A$12/(FREQUENCY(IF(A$2:A$12>0,MATCH(A$2:A$12,A$2:A$12,0)),ROW(A$2:A$12)-ROW(A$1))>0),ROWS(E$2:E2)),"") กด Ctrl+Shift+Enter
ต้องขอขอบคุณมากๆ เลยครับ แต่ขออีกนิดได้ไหมครับ คืออยากให้คำตอบมันจัดเรียงตามจำนวนที่ซ้ำด้วยครับ ตามตัวอย่างในภาพนี้ครับ
You do not have the required permissions to view the files attached to this post.
puriwutpokin
Guru
Posts: 3801 Joined: Fri Jan 04, 2013 9:49 pmLocation: BangkokExcel Ver: MS.365
#6
Post
by puriwutpokin Wed Jun 17, 2020 1:08 pm
ปรับเป็น E2=IFERROR(INDEX(A$2:A$12&"",MATCH(0,INDEX(COUNTIF(E$1:E1,A$2:A$12),0),0)),"")
ILoveExcel
Member
Posts: 69 Joined: Fri Jul 07, 2017 1:54 pmExcel Ver: 365
#7
Post
by ILoveExcel Wed Jun 17, 2020 1:22 pm
puriwutpokin wrote: Wed Jun 17, 2020 1:08 pm
ปรับเป็น E2=IFERROR(INDEX(A$2:A$12&"",MATCH(0,INDEX(COUNTIF(E$1:E1,A$2:A$12),0),0)),"")
สูตรใช้ได้ครับ แต่ยังไม่เรียงตามจำนวนมากไปหาน้อยครับ
You do not have the required permissions to view the files attached to this post.
puriwutpokin
Guru
Posts: 3801 Joined: Fri Jan 04, 2013 9:49 pmLocation: BangkokExcel Ver: MS.365
#8
Post
by puriwutpokin Wed Jun 17, 2020 3:21 pm
ปรับตามนี้ครับที่ E2=IF(ROWS(E$2:E2)>SUMPRODUCT(1/COUNTIF(A$2:A$12,A$2:A$12)),"",INDIRECT(TEXT(MOD(MIN(INDEX(-COUNTIF(A$2:A$12,A$2:A$12)*10^4*NOT(COUNTIF(E$1:E1,A$2:A$12))+ROW(A$2:A$12)*10^2+1,)),10^4),"R0C00"),))
ILoveExcel
Member
Posts: 69 Joined: Fri Jul 07, 2017 1:54 pmExcel Ver: 365
#9
Post
by ILoveExcel Wed Jun 17, 2020 3:39 pm
puriwutpokin wrote: Wed Jun 17, 2020 3:21 pm
ปรับตามนี้ครับที่ E2=IF(ROWS(E$2:E2)>SUMPRODUCT(1/COUNTIF(A$2:A$12,A$2:A$12)),"",INDIRECT(TEXT(MOD(MIN(INDEX(-COUNTIF(A$2:A$12,A$2:A$12)*10^4*NOT(COUNTIF(E$1:E1,A$2:A$12))+ROW(A$2:A$12)*10^2+1,)),10^4),"R0C00"),))
ทดลองปรับสูตรตามนี้แล้วครับ เบื้องต้นยังไม่พบปัญหาอะไร ขอบคุณมากๆ ครับ
You do not have the required permissions to view the files attached to this post.
Bo_ry
Gold
Posts: 1245 Joined: Sun Aug 12, 2018 12:11 amExcel Ver: MS 365
Contact:
#10
Post
by Bo_ry Wed Jun 17, 2020 10:18 pm
E2
You do not have the required permissions to view the files attached to this post.
ILoveExcel
Member
Posts: 69 Joined: Fri Jul 07, 2017 1:54 pmExcel Ver: 365
#11
Post
by ILoveExcel Thu Jun 18, 2020 8:37 am
Bo_ry wrote: Wed Jun 17, 2020 10:18 pm
E2
=IFERROR(INDEX(A:A,MOD(AGGREGATE(15,6,ROW($A$2:$A$12)-1/(1/FREQUENCY($A$2:$A$12,$A$2:$A$12))*1000,ROWS(E$2:E2)),1000)),"")
สูตรนี้ใช้ได้ตรงตามที่ต้องการเลยครับ ขอบคุณอาจารย์ทุกท่านมากๆ ครับ
linzhengli
Bronze
Posts: 349 Joined: Wed Mar 01, 2017 9:15 amExcel Ver: 2003
#12
Post
by linzhengli Thu Jun 18, 2020 9:36 am
ผมขอความอนุเคราะห์สูตรข้างต้นเป็น excel2003 บ้างครับ และขอบคุณมา ณ โอกาสนี้
Bo_ry
Gold
Posts: 1245 Joined: Sun Aug 12, 2018 12:11 amExcel Ver: MS 365
Contact:
#13
Post
by Bo_ry Thu Jun 18, 2020 2:34 pm
=IF(ROWS(E$2:E2)>COUNT(1/FREQUENCY($A$2:$A$12,$A$2:$A$12)),"",INDEX(A:A,MOD(SMALL(IF(FREQUENCY($A$2:$A$12,$A$2:$A$12),ROW($A$2:$A$13)-FREQUENCY($A$2:$A$12,$A$2:$A$12)*1000),ROWS(E$2:E2)),1000)))
snasui
Site Admin
Posts: 31255 Joined: Sun Jan 24, 2010 12:33 pmLocation: Songkhla, ThailandExcel Ver: 2010, 2019
Contact:
#14
Post
by snasui Thu Jun 18, 2020 7:58 pm
แถมอีกสูตรครับ
E2 คีย์
=IF(ROWS($2:2)>COUNT(1/FREQUENCY($A$2:$A$12,$A$2:$A$12)),"",MODE(IF(ISNA(MATCH(IF({1,1},$A$2:$A$12),E$1:E1,0)),IF({1,1},$A$2:$A$12))))
Ctrl+Shift+Enter > Copy ลงด้านล่าง
linzhengli
Bronze
Posts: 349 Joined: Wed Mar 01, 2017 9:15 amExcel Ver: 2003
#15
Post
by linzhengli Thu Jun 18, 2020 8:57 pm
ขอบคุณในวิทยาทานของทุกท่านมา ณ โอกาสนี้
snasui.com ยินดีต้อนรับ 
สมาชิกท่านใดที่ยังไม่ได้ระบุ Version ของ Excel ที่ใช้งานจริง สามารถทำตาม Link นี้เพื่อจะได้รับคำตอบที่ตรงกับ Version ของท่านครับ 
โปรดทราบ 
