Page 1 of 1
สอบถาม2ข้อครับกำลังจะขึ้นระบบใหม่
Posted: Mon Sep 26, 2016 5:47 pm
by pupepake
สอบถาม2ข้อครับกำลังจะขึ้นระบบใหม่ ข้อมูลเดิมอยู่ในcell เดียวกัน ต้องการแยกข้อมูลออกจากกัน จะวางสูตรอย่างไรครับ
ถามปัญหา.xlsx
Re: สอบถาม2ข้อครับกำลังจะขึ้นระบบใหม่
Posted: Mon Sep 26, 2016 9:08 pm
by snasui
ตัวอย่างสูตรครับ
เซลล์ B3 คีย์
=IFERROR(MID(A3,LEN(LOOKUP(2,1/SEARCH($D$3:$D$17,A3),$D$3:$D$17))+2,255),A3)
Enter > Copy ลงด้านล่าง
Re: สอบถาม2ข้อครับกำลังจะขึ้นระบบใหม่
Posted: Tue Sep 27, 2016 8:50 am
by pupepake
ปัญหา1 ใช้ได้แล้วครับท่านอาจารย์ ขอบพระคุณมากครับ
Re: สอบถาม2ข้อครับกำลังจะขึ้นระบบใหม่
Posted: Tue Sep 27, 2016 10:49 am
by DhitiBank
ลองแบบนี้ครับ
B2
=TRIM(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(A2,C2,""),D2,""),E2,""))
C2
=TRIM(LEFT(SUBSTITUTE(MID($A2,LOOKUP(2,1/ISNUMBER(SEARCH({"ต.";"ตำบล";"แขวง"},$A2)),SEARCH({"ต.";"ตำบล";"แขวง"},$A2)),255),CHAR(160),REPT(" ",20)),20))
D2
=TRIM(LEFT(SUBSTITUTE(MID($A2,LOOKUP(2,1/ISNUMBER(SEARCH({"อ.";"อำเภอ";"เขต"},$A2)),SEARCH({"อ.";"อำเภอ";"เขต"},$A2)),255),CHAR(160),REPT(" ",20)),20))
E2
=TRIM(LEFT(SUBSTITUTE(MID($A2,LOOKUP(2,1/ISNUMBER(SEARCH({"จ.";"จังหวัด";"กทม";"กรุงเ"},$A2)),SEARCH({"จ.";"จังหวัด";"กทม";"กรุงเ"},$A2)),255),CHAR(160),REPT(" ",20)),20))
ทุกสูตรคีย์เสร็จกด Enter >> คัดลอกลงล่างครับ
แต่ดูเหมือนว่าตัวอย่างแรกที่ A2 คำว่า "กรุงเทพฯ" คีย์ต่อท้ายเข้าไปเองหรือเปล่าครับ เพราะอักขระที่คั่นชื่อจังหวัดกับอำเภอต่างจากตัวอย่างอื่นๆ
2016-09-27 10_45_20-Microsoft Excel - การตัดคำ.xls.png
Re: สอบถาม2ข้อครับกำลังจะขึ้นระบบใหม่
Posted: Tue Sep 27, 2016 2:29 pm
by pupepake
ถูกต้องครับ "กรุงเทพฯ"ผมคีย์ต่อเข้าไปเอง.. ปัญหาที่ 2 ใช้ได้ตามวัถุประสงค์ครับ ผมมีข้อมูล สองพันกว่ารายการ ใส่สูตร 5 นาทีเสร็จ ประหยัดเวลามาก ขอบพระคุณที่กรุณาช่วยเหลือนะครับ ขอบคุณมากครับ
