Snasui Excel Forum

หนูอยากให้ค่าของชื่อเดียวกันให้ไปอยู่รวมกัน รายละเอียดตามภาพเลยค่ะ
รบกวนด้วยนะคะ

แนบไฟล์ตัวอย่างมาด้วยเพื่อให้เพื่อนๆเข้าถึงปัญหาได้ง่าย และ สะดวกต่อการตอบคำถามครับ

ขอโทษค่ะ ลืมแนบ! รบกวนด้วยนะคะ

ที่ cell c4 มีเว้นวรรคหลังคำว่ามะม่วงลบวรรคนั้นออกด้วยครับ

ที่ F2 คีย์
=SUMPRODUCT(1/COUNTIF(OFFSET($C$3,1,,COUNTA($C:$C)-1,),OFFSET($C$3,1,,COUNTA($C:$C)-1,))) กด Enter

ที่ F4 คีย์
=IF(ROWS(F$4:F4)>$F$2,"",INDEX($C$4:$C$12,SMALL(IF(MATCH($C$4:$C$12,$C$4:$C$12,0)=ROW($C$4:$C$12)-ROW($C$4)+1,ROW($C$4:$C$12)-ROW($C$4)+1),ROWS(F$4:F4)))) กด Ctrl+Shift+Enter copy ลง

ที่ G4 คีย์
=SUMIF($C$4:$C$12,$F4,$D$4:$D$12) กด Enter และ copy ลง

ที่ H4 คีย์ (ตรงนี้ไม่ค่อยแน่ใจว่าจะได้ตามที่ต้องการครับ รอท่านอื่นมาเพิ่มเติมนะครับ)
=VLOOKUP($F4,CHOOSE({1,2},$C$4:$C$12,$B$4:$B$12),2,0) กด Enter และ copy ลง

ที่ H4 คีย์

=INDEX($B$4:$B$12,(SMALL(IF((F4=$C$4:$C$12),ROW($C$4:$C$12)-ROW($A$4)+1),ROW($R$1))))&","&IFERROR(INDEX($B$4:$B$12,(SMALL(IF((F4=$C$4:$C$12),ROW($C$4:$C$12)-ROW($A$4)+1),ROW($R$2)))),"")

กด Ctrl+Shift+Enter
จะมีติ่งนะครับ รอท่านอื่นมาเพิ่มเติมนะครับในการตัดติ่งออก

อีกตัวอย่างสูตรตามด้านล่างครับ

1. ที่ E4 คีย์
   =IFERROR(LOOKUP(2,1/(C$3:C3=C4),E$3:E3)&","&B4,B4)
   Enter > Copy ลงด้านล่าง
2. ที่ F4 คีย์
   =IFERROR(INDEX($C$4:$C$12,SMALL(IF(FREQUENCY(MATCH($C$4:$C$12,$C$4:$C$12,0),ROW($C$4:$C$12)-ROW($C$4)+1),ROW($C$4:$C$12)-ROW($C$4)+1),ROWS(F$4:F4))),"")
   Ctrl+Shift+Enter > Copy ลงด้านล่าง
3. ที่ G4 คีย์
   =SUMIF($C$4:$C$12,F4,$D$4:$D$12)
   Enter > Copy ลงด้านล่าง
4. ที่ H4 คีย์
   =LOOKUP(2,1/($C$4:$C$12=F4),$E$4:$E$12)
   Enter > Copy ลงด้านล่าง

!

Note: Ctrl+Shift+Enter เป็นการสร้างสูตร Array โดยสามารถเลือกดำเนินการตามข้อ 1 หรือ 2 ด้านล่าง กรณีคีย์สูตรเอง เมื่อคีย์สูตรแล้ว แทนที่จะกด Enter ให้กดแป้น Ctrl และ Shift พร้อมกันค้างไว้แล้วกด Enter เพื่อสร้างเป็นสูตร Array กรณี Copy สูตรไปวางให้กดแป้น F2 เพื่อทำการ Edit Cell นั้นก่อน จากนั้นกดแป้น Ctrl และ Shift พร้อมกันค้างไว้แล้วตามด้วย Enter เพื่อสร้างเป็นสูตร Array หากกดแป้นถูกต้องสูตรนั้นจะมีเครื่องหมายปีกกาครอบ เช่น {=YourFormulas(...)} ปีกกานี้ไม่สามารถคีย์เข้าไปเอง จะต้องมาด้วยการกดแป้น Ctrl+Shift+Enter เท่านั้น ถ้ายังไม่เห็นปีกกาครอบสูตรแสดงว่ากดแป้นให้รับสูตรไม่ถูกต้อง การแก้ไขเปลี่ยนแปลงสูตร Array จะต้องกดแป้นให้รับสูตรด้วย Ctrl+Shift+Enter ทุกครั้ง

ขอบคุณมากค่ะๆ ได้แล้วๆ