Snasui Excel Forum

ในหน้า daily report จะเป็นการลงบันทึกยอดขายรายวัน ผมต้องการให้ เลข Invoice วันที่ และยอดขาย ไปอยู่ที่หน้าฐานข้อมูล ต้องใช้สูตรอะไรครับ โดยที่ลูกค้ามีการขายซ้ำในเดือนถัดไป ถ้ามีการขายซ้ำลูกค้าเดิมอยากจะให้เลข invoice ไปปรากฎที่ INV2 date2 ยอดขาย2 ครับ ขอบคุณครับ

Database sheet

L
=IF($B2=Sheet2!$M$2:$M$33,Sheet2!A$2:A$33,"")
M
=IF($B2=Sheet2!$M$2:$M$33,Sheet2!B$2:B$33,"")
N
=IF($B2=Sheet2!$M$2:$M$33,Sheet2!K$2:K$33,"")

O
=SMALL(IF($B2=Sheet2!$M$2:$M$33,Sheet2!A$2:A$33,""),2)
P
=SMALL(IF($B2=Sheet2!$M$2:$M$33,Sheet2!B$2:B$33,""),2)
Q
=SMALL(IF($B2=Sheet2!$M$2:$M$33,Sheet2!C$2:C$33,""),2)

ปล. เปลี่ยน 33 ไปจนสุดตาราง

ลองทำดูแล้ว ได้เรียบร้อยครับ ขอบพระคุณมากๆเลยครับ ถ้าสงสัยตรงไหนจะถามเพิ่มนะครับ

สอบถามเพิ่มเติมครับ ผมลองใช้สูตร SMALL แล้ว ค่า INV แรกได้ค่าถูกต้องครับ แต่เป็น INV2 ได้เป็น #NUM ครับ แต่สูตรถ้าใส่เป็นเลข 1 จะได้ INV1 ปกติครับ

ลบค่า #NUM /
ใช้เลข 2 เพราะค่าลำดับที่ 2 (INV2) จากค่าตัวแปรซ้ำ (INV).

=IFERROR(SMALL(IF($B2=Sheet2!$M$2:$M$1000,Sheet2!A$2:A$1000,""),2),"")

ลูกค้าที่มี invที่ 2 ไม่ขึ้นค่าครับ ขึ้นแต่ค่า inv ที่ 1 ไม่ทราบว่าต้องแก้ไขตรงไหนหรอครับ ผมรบกวนช่วยทำไฟล์ตัวอย่างให้ดูหน่อยได้มั๊ยครับ ตอนนี้ผมทำได้แต่ค่า INV ที่ 1 แต่ค่า INV ที่ 2 เป็นต้นไป ไม่ขึ้นเลยครับ ขึ้นแต่ #NUM!

แนบไฟล์ล่าสุดพร้อมแจ้งปัญหา ณ ปัจจุบัน จะได้ตอบต่อไปจากนั้นครับ

ตอนนี้ได้เป็นแบบนี้ครับอาจารย์

ผมสงสัยต่อครับอาจารย์ ถ้าในกรณีที่เลข inv มันไม่ได้เพิ่มขึ้น ในเดือนถัดไป เช่น เดือน 6 มีการขาย เลข INV 6000 แต่เดือน 7 มีการคืนสินค้า เลข INV สำหรับการคืนสินค้าคือ 260 จะใช้สูตรยังไงหรอครับ

phatcharapon wrote: Wed Jul 25, 2018 9:43 am ในหน้า daily report จะเป็นการลงบันทึกยอดขายรายวัน ผมต้องการให้ เลข Invoice วันที่ และยอดขาย ไปอยู่ที่หน้าฐานข้อมูล ต้องใช้สูตรอะไรครับ โดยที่ลูกค้ามีการขายซ้ำในเดือนถัดไป ถ้ามีการขายซ้ำลูกค้าเดิมอยากจะให้เลข invoice ไปปรากฎที่ INV2 date2 ยอดขาย2 ครับ ขอบคุณครับ

ตัวอย่างสูตรครับ

1. ชีต Daily Report เซลล์ M1 ปรับสูตรเป็น
   =IFERROR(IF(ISBLANK(S2),VLOOKUP(L2,DatabaseSheet!$B$2:$G$981,1,0),INDEX(DatabaseSheet!$B$2:$B$981,MATCH(S2,DatabaseSheet!$H$2:$H$981,0))),"")
   Enter > Copy ลงด้านล่าง
2. ที่ DatabaseSheet เซลล์ L2 คีย์
   =IFERROR(INDEX('Daily Report'!$A$2:$A$467,SMALL(IF('Daily Report'!$M$2:$M$467=$B2,ROW('Daily Report'!$A$2:$A$467)-ROW('Daily Report'!$A$2)+1),COUNTIF($L$1:$L1,LEFT(L$1,3)&"*"))),"")
   Ctrl+Shift+Enter > Copy ลงด้านล่าง
3. ทที่ DatabaseSheet เซลล์ M2 คีย์
   =IFERROR(INDEX('Daily Report'!$B$2:$B$467,SMALL(IF('Daily Report'!$M$2:$M$467=$B2,ROW('Daily Report'!$A$2:$A$467)-ROW('Daily Report'!$A$2)+1),COUNTIF($L$1:$L1,LEFT(L$1,3)&"*"))),"")
   Ctrl+Shift+Enter > Copy ลงด้านล่าง
4. ที่ DatabaseSheet เซลล์ N2 คีย์
   =IFERROR(INDEX('Daily Report'!$K$2:$K$467,SMALL(IF('Daily Report'!$M$2:$M$467=$B2,ROW('Daily Report'!$A$2:$A$467)-ROW('Daily Report'!$A$2)+1),COUNTIF($L$1:$L1,LEFT(L$1,3)&"*"))),"")
   Ctrl+Shift+Enter > Copy ลงด้านล่าง
5. ปรับ L2:N2 ไปใช้กับคอลัมน์ที่เหลือ

phatcharapon wrote: Fri Jul 27, 2018 6:40 pm ผมสงสัยต่อครับอาจารย์ ถ้าในกรณีที่เลข inv มันไม่ได้เพิ่มขึ้น ในเดือนถัดไป เช่น เดือน 6 มีการขาย เลข INV 6000 แต่เดือน 7 มีการคืนสินค้า เลข INV สำหรับการคืนสินค้าคือ 260 จะใช้สูตรยังไงหรอครับ

ให้ตรวจสอบคำตอบตามด้านบนว่าตรงกับที่ต้องการเรียบร้อยแล้วค่อยนำคำถามนี้มาถามกันต่อ ตอนนี้อ่านแล้วยังไม่กระจ่าง ควรจะยกตัวอย่างให้เห็นชัดเจนว่าค่าที่พูดถึงอยู่ในเซลล์ไหน อย่างไร

การทำตัวอย่างข้อมูลควรจะตัดมาเพียงบางส่วนจะได้สะดวกต่อการอธิบายและการตอบ ตรวจสอบได้เร็วครับ

ขอบคุณมากๆครับอาจารย์ ทำได้แล้วครับ คราวหน้าจะตัดเฉพาะข้อมูลตัวอย่างมาถามนะครับ