Page 1 of 1
อยากสอบถามเขียนสูตร ให้แสดงค่าตามต้องการ
Posted: Tue Oct 02, 2018 11:37 am
by Aantsugar
อยากให้คอล์ม D แสดงค่าตามที่กำหนด เช่น B004-000 ก็ให้คอล์ม D แสดงค่า A คะ
ตามค่าที่กำหนดคะ ต้องเขียนสูตรยังไงคะ
ตามไฟล์แนบคะ ขอบคุณคะ
Re: อยากสอบถามเขียนสูตร ให้แสดงค่าตามต้องการ
Posted: Tue Oct 02, 2018 11:56 am
by parakorn
D2 =IFERROR(VLOOKUP(LOOKUP(2,1/($A$2:$A2<>""),$A$2:$A2),$F$2:$G$5,2,0),"") Enter+Copy ลงด้านล่าง
Re: อยากสอบถามเขียนสูตร ให้แสดงค่าตามต้องการ
Posted: Wed Oct 03, 2018 9:15 am
by Aantsugar
parakorn wrote: Tue Oct 02, 2018 11:56 am
D2 =IFERROR(VLOOKUP(LOOKUP(2,1/($A$2:$A2<>""),$A$2:$A2),$F$2:$G$5,2,0),"") Enter+Copy ลงด้านล่าง
ขอบคุรมากคะ ได้แล้ว
Re: อยากสอบถามเขียนสูตร ให้แสดงค่าตามต้องการ
Posted: Thu Oct 04, 2018 9:35 am
by Aantsugar
Aantsugar wrote: Wed Oct 03, 2018 9:15 am
parakorn wrote: Tue Oct 02, 2018 11:56 am
D2 =IFERROR(VLOOKUP(LOOKUP(2,1/($A$2:$A2<>""),$A$2:$A2),$F$2:$G$5,2,0),"") Enter+Copy ลงด้านล่าง
ขอบคุรมากคะ ได้แล้ว
รบกวนอีกอย่างคะ ถ้าเราอยากรวมข้อมูลใน Sheet1 และ Sheet2
มาแสดงในSheet3 เขียนสูตรยังไงคะ
ตามไฟล์แนบ ขอบคุณคะ
Re: อยากสอบถามเขียนสูตร ให้แสดงค่าตามต้องการ
Posted: Thu Oct 04, 2018 7:21 pm
by Bo_ry
Sheet3 A2
=IFERROR(IFERROR(LOOKUP(CHAR(255),Sheet2!A$2:INDEX(Sheet2!A$1:A$99,AGGREGATE(15,6,ROW(B$2:B$99)/(Sheet2!$B$2:$B$99<>""),ROWS(B$2:B2)))),LOOKUP(CHAR(255),Sheet1!A$2:INDEX(Sheet1!A$1:A$99,AGGREGATE(15,6,ROW(B$2:B$99)/(Sheet1!$B$2:$B$99<>""),ROWS(B$2:B2)-COUNTA(Sheet2!$B$2:$B$99))))),"")
Sheet3 B2 ลากไป C2
=IFERROR(IFERROR(INDEX(Sheet2!B$1:B$99,AGGREGATE(15,6,ROW(B$2:B$99)/(Sheet2!$B$2:$B$99<>""),ROWS(B$2:B2))),INDEX(Sheet1!B$1:B$99,AGGREGATE(15,6,ROW(B$2:B$99)/(Sheet1!$B$2:$B$99<>""),ROWS(B$2:B2)-COUNTA(Sheet2!$B$2:$B$99)))),"")
เลือก A2:C2 ลากลง
TEST11.xlsx
Re: อยากสอบถามเขียนสูตร ให้แสดงค่าตามต้องการ
Posted: Fri Oct 05, 2018 10:53 am
by Aantsugar
Bo_ry wrote: Thu Oct 04, 2018 7:21 pm
Sheet3 A2
=IFERROR(IFERROR(LOOKUP(CHAR(255),Sheet2!A$2:INDEX(Sheet2!A$1:A$99,AGGREGATE(15,6,ROW(B$2:B$99)/(Sheet2!$B$2:$B$99<>""),ROWS(B$2:B2)))),LOOKUP(CHAR(255),Sheet1!A$2:INDEX(Sheet1!A$1:A$99,AGGREGATE(15,6,ROW(B$2:B$99)/(Sheet1!$B$2:$B$99<>""),ROWS(B$2:B2)-COUNTA(Sheet2!$B$2:$B$99))))),"")
Sheet3 B2 ลากไป C2
=IFERROR(IFERROR(INDEX(Sheet2!B$1:B$99,AGGREGATE(15,6,ROW(B$2:B$99)/(Sheet2!$B$2:$B$99<>""),ROWS(B$2:B2))),INDEX(Sheet1!B$1:B$99,AGGREGATE(15,6,ROW(B$2:B$99)/(Sheet1!$B$2:$B$99<>""),ROWS(B$2:B2)-COUNTA(Sheet2!$B$2:$B$99)))),"")
เลือก A2:C2 ลากลง
TEST11.xlsx
ลองทำตามสูตรแล้ว ไม่ได้แสดงรหัสคลังคะ ไม่ทราบว่าต้องปรับสูตรยังไงคะ ขอบคุณคะ
Re: อยากสอบถามเขียนสูตร ให้แสดงค่าตามต้องการ
Posted: Fri Oct 05, 2018 4:10 pm
by Bo_ry
Invecode.jpg
รูปจาก ไฟล์ใน #5 ก็แสดงครบนะคะ
Re: อยากสอบถามเขียนสูตร ให้แสดงค่าตามต้องการ
Posted: Sat Oct 06, 2018 11:05 am
by Aantsugar
Bo_ry wrote: Fri Oct 05, 2018 4:10 pm
Invecode.jpg
รูปจาก ไฟล์ใน #5 ก็แสดงครบนะคะ
ไม่รู้ว่าเกี่ยวกับเวอร์ชั่น Excel ที่ใช้ไหมคะ เพราะเปิดมาแล้วก็ไม่ขึ้นรหัสคลังคะ
ตามแนบรูปเลยคะ
อันนี้ใช้ Excel เวอร์ชั่น 2007 คะ มีวิธีแก้ไขยังไงไหมคะ
Re: อยากสอบถามเขียนสูตร ให้แสดงค่าตามต้องการ
Posted: Sat Oct 06, 2018 12:24 pm
by Bo_ry
เกี่ยวค่ะ Excel 2007 ยังไม่มี function Aggregate ขอโทษค่ะ ไม่ได้นึกถึง version
A2 ใส่สูตรแล้วกด Ctrl+Shift+Enter
=IFERROR(IFERROR(LOOKUP(CHAR(255),Sheet2!A$2:INDEX(Sheet2!A$1:A$99,SMALL(IF(Sheet2!$B$2:$B$99<>"",ROW(B$2:B$99)),ROWS(B$2:B2)))),LOOKUP(CHAR(255),Sheet1!A$2:INDEX(Sheet1!A$1:A$99,SMALL(IF(Sheet1!$B$2:$B$99<>"",ROW(B$2:B$99)),ROWS(B$2:B2)-COUNTA(Sheet2!$B$2:$B$99))))),"")
B2 ใส่สูตรแล้วกด Ctrl+Shift+Enter ลากไป C2
=IFERROR(IFERROR(INDEX(Sheet2!B$1:B$99,SMALL(IF(Sheet2!$B$2:$B$99<>"",ROW(B$2:B$99)),ROWS(B$2:B2))),INDEX(Sheet1!B$1:B$99,SMALL(IF(Sheet1!$B$2:$B$99<>"",ROW(A$2:A$99)),ROWS(A$2:A2)-COUNTA(Sheet2!$B$2:$B$99)))),"")
เลือก A2:C2 ลากลง
TEST11.xlsx
Re: อยากสอบถามเขียนสูตร ให้แสดงค่าตามต้องการ
Posted: Sat Oct 06, 2018 1:52 pm
by Aantsugar
Bo_ry wrote: Sat Oct 06, 2018 12:24 pm
เกี่ยวค่ะ Excel 2007 ยังไม่มี function Aggregate ขอโทษค่ะ ไม่ได้นึกถึง version
A2 ใส่สูตรแล้วกด Ctrl+Shift+Enter
=IFERROR(IFERROR(LOOKUP(CHAR(255),Sheet2!A$2:INDEX(Sheet2!A$1:A$99,SMALL(IF(Sheet2!$B$2:$B$99<>"",ROW(B$2:B$99)),ROWS(B$2:B2)))),LOOKUP(CHAR(255),Sheet1!A$2:INDEX(Sheet1!A$1:A$99,SMALL(IF(Sheet1!$B$2:$B$99<>"",ROW(B$2:B$99)),ROWS(B$2:B2)-COUNTA(Sheet2!$B$2:$B$99))))),"")
B2 ใส่สูตรแล้วกด Ctrl+Shift+Enter ลากไป C2
=IFERROR(IFERROR(INDEX(Sheet2!B$1:B$99,SMALL(IF(Sheet2!$B$2:$B$99<>"",ROW(B$2:B$99)),ROWS(B$2:B2))),INDEX(Sheet1!B$1:B$99,SMALL(IF(Sheet1!$B$2:$B$99<>"",ROW(A$2:A$99)),ROWS(A$2:A2)-COUNTA(Sheet2!$B$2:$B$99)))),"")
เลือก A2:C2 ลากลง
TEST11.xlsx
ได้ละคะ ขอบคุณคะ สำหรับคำแนะนำ และการเขียนสูตร
