Snasui Excel Forum

ถ้า column D เป็นสาขา (ข้อความที่อยู่ column Z, high light สีเหลือง) และ column O เป็น CAH ให้คำนวณ โดยเอา column P * 33% ถ้าไม่ใช่ให้คำนวณ 32%

ต้องปรับสูตรอย่างไรคะ เพราะมีข้อมูลเยอะมากต้องมานั่งเปลี่ยนทุกครั้งค่ะ

ลองดูครับ

=IF(O14="CAH",P14*33%,P14*32%)

เอาใหม่ค่ะ
ถ้า column D เป็นสาขา (ข้อความที่อยู่ column Z, high light สีเหลือง) และ column O เป็น CAH ให้คำนวณ โดยเอา column P * 33% ถ้าไม่ใช่ให้คำนวณ 32%

และถ้า column Dเป็น สาขา และ column O เป็น STE ให้คำนวณ column P*32%*-1

ต้องปรับสูตรอย่างไรคะ เพราะมีข้อมูลเยอะมากต้องมานั่งเปลี่ยนทุกครั้งค่ะ

เช่น

Ubon CAH 2,920.29

Ubon STE -2,831.80

Team1 CAH 2,530.77

Team1 STE -2,690.11

ลองดูว่าใช่ตามที่ต้องการหรือไม่ครับ

T9 =IF(SUMPRODUCT((D9=$Z$13:$Z$18)*(O9="CAH"))>0,P9*33%,IF(SUMPRODUCT((D9=$Z$13:$Z$18)*(O9="STE"))>0,P9*32*-1,P9*32%)) Enter+Copy ลงด้านล่างครับ

เกือบถูกแล้วค่ะ ผิดที่ high light สีส้ม ต้องเป็นยอดติดลบค่ะ ถ้าเป็น STE ต้องติดลบเสมอค่ะ

T9
=((O9="CAH")*COUNTIF($Z$13:$Z$18,D9)+32)%*P9*SIGN(0.5-(O9=$O$10))

ได้แล้วค่ะ ขอบคุณ K.Bo_ry มากค่ะ

ถ้าสาขา ได้ CAH คิด 33.5%
ถ้าสาขาได้ STE คิด 32%*-1

ถ้าสนงได้ STE หจือ CAH คิด 32%*-1 ทั้งหมด


ไม่เข้าใจสูตร =SIGN(0.5-(O9=$O$10)) คืออะไรคะ ถ้าต้องปรับเปลี่ยน % ในอนาคต ต้องปรับอย่างไรคะ

T9
=((O9="CAH")*COUNTIF($Z$13:$Z$18,D9)*1.5+32)%*P9*SIGN(0.5-(O9="STE"))


Sign สำหรับคิดเครื่องหมาย + - หรือ 0
ถ้า O9 เป็น STE
=SIGN(0.5-(O9="STE"))
=SIGN(0.5-(TRUE)) = =SIGN(0.5-1) =SIGN(-0.5) = -1
ถ้า O9 ไม่เป็น STE
=SIGN(0.5-(FALSE)) = =SIGN(0.5-0) =SIGN(0.5) = +1


32% กับ 33.5% ต่างกัน 1.5 %
=((O9="CAH")*COUNTIF($Z$13:$Z$18,D9)*1.5+32)%

ถ้า (O9="CAH") และ COUNTIF($Z$13:$Z$18,D9) คือมี D9 ใน สาขา $Z$13:$Z$18
True*1 *1.5 +32 = 1.5 +32 = 33.5

ถ้า O9 <> "CAH" และ/หรือ D9 ไม่มีใน สาขา $Z$13:$Z$18
0*0*1.5 + 32 = 0 + 32 = 32
1*0*1.5 + 32 = 0 + 32 = 32
0*1*1.5 + 32 = 0 + 32 = 32

ขอโทษค่ะ คิดการคำนวณผิด ต้อง

ถ้าสาขา ได้ CAH คิด 33.5%

ถ้าสาขาได้ STE คิด reverse amt ทั้งก้อน*-1

ถ้าสนงได้ CAH คิด 32%

ถ้าสนงได้ STE คิด reverse amt ทั้งก้อน*-1

สำนักงาน คือไม่มีในสาขา Z13:Z18 รึเปล่า
ทำไม
Row9, Row14 CAH แต่ * -1

คำตอบที่ถูกต้องดูที่row 21 ถึง row 29 ค่ะ

=IF((O9="CAH")*COUNTIF($Z$13:$Z$18,D9),33.5%,-1)*P9

เงื่อนไขตามที่อธิบายไม่ต้องกับคำตอบใน Row 21:29

ถ้าสาขา ได้ CAH คิด 33.5%
นอกนั้น * -1

มีคิด 32% ด้วยค่ะ สำหรับ สนง เช่น team1 team2 H1 H2 จะไม่รวมอยู่ใน ตารางสีเหลือง ก็ถือว่าเป็น สำนักงานค่ะ ถ้าสาขา (ที่เป็นcolumn Z สีเหลือง)มีเงื่อนไขพิเศษ ถ้าได้CHA คิด33.5% ถ้าไม่ใช่ ก็reverse ทั้งจำนวน *-1 ค่ะ

ถ้าสาขา ได้ CAH คิด 33.5%

ถ้าสาขาได้ STE คิด reverse amt ทั้งก้อน*-1

ถ้าสนงได้ CAH คิด 32%

ถ้าสนงได้ STE คิด reverse amt ทั้งก้อน*-1

Bo_ry wrote: Tue Jul 02, 2019 5:48 pm ทำไม
Row9, Row14 CAH แต่ * -1

แล้วทำไม
D9 => H1 O9=> CAH คิด 8472.39*-1

D14 => Team4 O14 => CAH คิด 8562.9*-1

ขอโทษค่ะ คิดการคำนวณผิดเอง ต้อง

ที่ถูกต้อง HO CAH คิด 32%

ขอโทษค่ะ คิดการคำนวณผิดเอง ต้อง

ที่ถูกต้อง HO CAH คิด 32% เกือบได้แล้วค่ะ

ลองปรับตามเดิมนิดเป็น
T9=IF((O9="CAH")*COUNTIF($AA$13:$AA$18,D9),33.5%,IF(O9="CAH",32%,-1))*P9

T9 =IF(O9="CAH",(32+COUNTIF($Z$13:$Z$18,D9)*1.5)%,-1)*P9

ได้แล้วค่ะ ขอบคุณทั้งสองท่านค่ะ