Snasui Excel Forum

ผมมีข้อมูล ตัวเลข 5 คอมลัมน์ เช่น ช่อง 1 200 ช่อง 2 300 ประมาณนี้ครับ
แปรให้เป็น ลักษณะการใช้ประโยชน์ เช่น 1 เกษตรกรรม 2 ที่อยู่อาศัย 3 อื่นๆ เป็นต้น ครับ
ตามไฟล์ ครับ

ต้องการคำตอบในคอลัมน์ไหนครับ

ตอบใน คอลัมน์ J และ k ครับ

ตัวอย่างสูตรใน Excel 2019 หรือ 365 ครับ

เซลล์ J4

=TEXTJOIN(",",TRUE,IF(ISNUMBER(A4:E4),COLUMN(A4:E4),""))

Ctrl+Shift+Enter > Copy ลงด้านล่าง

เซลล์ K4

=TEXTJOIN(",",TRUE,IF(ISNUMBER(A4:E4),$A$1:$E$1,""))

Ctrl+Shift+Enter > Copy ลงด้านล่าง

ขอบคุณมากครับ
ลบกวนพี่มากเลยครับ
มีหลายคำถามเลยครับ

ผมสร้างฟอรัมไว้เพื่อไว้ถามตอบกัน ถามกันได้ตามสะดวกไม่ต้องเกรงอกเกรงใจครับ

ข้อมูล ตาราง 1 ที่มี ช่อง A - E
ให้หาค่า จาก ตาราง 2 ช่อง G H
ให้ออก ช่อง J K
ไม่เห็นออก เป็น แบบ ช่อง J K ครับ

ได้ค่าเป็นแบบไหน อย่างไร ลองจับภาพ + แนบไฟล์ที่ Update ล่าสุดมาดูกันครับ

จะเป็น NAME ครับ

ก็แสดงว่าไม่ได้ใช้ Excel 2019 หรือ 365 ครับ

ตัวอย่างสูตรตามด้านล่างครับ

1. ที่ M3 คีย์เครื่องหมาย ,
   Enter
2. ที่ M4 คีย์
   =IF(A4<>"",COLUMNS($A4:A4),"")
   Enter > Copy ไปด้านขวาถึง Q4 > Copy ลงด้านล่าง
3. ที่ R4 คีย์
   =IF(A4<>"",A$1,"")
   Enter > Copy ไปด้านขวาถึง V4 > Copy ลงด้านล่าง
4. ที่ J4 คีย์
   =SUBSTITUTE(TRIM(SUBSTITUTE(CONCATENATE(M4,$M$3,N4,$M$3,O4,$M$3,P4,$M$3,Q4,$M$3),","," "))," ",",")
   Enter > Copy ลงด้านล่าง
5. ที่ K4 คีย์
   =SUBSTITUTE(TRIM(SUBSTITUTE(CONCATENATE(R4,$M$3,S4,$M$3,T4,$M$3,U4,$M$3,V4,$M$3),","," "))," ",",")
   Enter > Copy ลงด้านล่าง

ใช้สูตรเยอะมากเลยครับ

ขอบคุณมากครับ

อีกแบบ
J4
=IF(E4,"(5) ","")&SUBSTITUTE(TRIM(SUBSTITUTE(TEXT(SUMPRODUCT(COLUMN(A4:D4)*(A4:D4>0),10^(4-COLUMN(A4:D4))),"0 0 0 0"),0,))," ",",")

K4
=SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(J4,1,$A$1),2,$B$1),3,$C$1),4,LEFT($D$1,FIND("/",$D$1)-1)),5,$E$1),","," , ")