Page 1 of 1
Drop Down List ไม่ให้โชว์ตัวซ้ำกัน และ ให้ Drop Down List เป็นชั้นๆ ต้องทำยังไง ครับ
Posted: Sun Sep 20, 2020 8:09 pm
by xsilver
คือผม ลองหาวิธีทำ Drop Down List ตัดคำที่ ซ้อนกัน ออก แต่ผมทำไม่ได้ ต้องใช้ สูตรตัวไหน ครับ โดยจะ ยกมากจาก อีก sheet
และ Drop Down List สามารถเลือก ทีละอันเรียงมา ทีละ คอลัม ผมต้องใช้ สูตรยังไง ครับ ผมทำไม่ได้
พยายาม แล้วก็ไม่ได้
Re: Drop Down List ไม่ให้โชว์ตัวซ้ำกัน และ ให้ Drop Down List เป็นชั้นๆ ต้องทำยังไง ครับ
Posted: Sun Sep 20, 2020 8:14 pm
by snasui
กรุณา Update Version Excel ที่ใช้ โดยดูวิธีการจาก Link นี้ครับ
https://www.snasui.com/viewtopic.php?f= ... 77#p103177
จากนั้นช่วยอธิบายรายละเอียดพร้อมแสดงตัวอย่างคำตอบที่ต้องการมาในไฟล์ด้วยว่าต้องการแสดงคำตอบที่ชีตไหน ด้วยค่าเท่าใดบ้างครับ
Re: Drop Down List ไม่ให้โชว์ตัวซ้ำกัน และ ให้ Drop Down List เป็นชั้นๆ ต้องทำยังไง ครับ
Posted: Mon Sep 21, 2020 9:06 am
by xsilver
Excel 2013 ครับ อัพเดท แล้วครับ อาจาย์
คือผม ทำรายการสินค้า ไว้ ใน ชีท Data CPU และ ชีท Data MB ครับ แล้วผมใช้ การดึงข้อมูลมาใช้ ชีท Spec โดยวิธีการ Drop Down ครับ
โดยมี ลักษณะ แบบนี้ครับ
คอลัมน์ B ผมต้องการเลือก Brand ของ CPU ที่ผมอยากได้ ครับ แต่เหมือนทำ Drop Down แล้ว มันเป็นชื่อหลายอัน มีวิธีทำค่าที่ซ้ำให้หายไปไหมครับ
คอลัมน์ C ผมต้องการเลือก Brand ของ CPU แล้วเช่น AMD ให้ออก แต่ Data ที่เชื่อมกันกับ AMD เท่านั้น เลือก Intel ก็เชื่อมกับ Intel เท่านั้นเช่น
เลือก AMD แล้ว ก็จะเห็นแต่ พวก Ryzen ที่เป็นสินค้าของ AMD ที่ผมทำไว้ใน ชีท Data CPU
เลือก Intel แล้ว ก็จะเห็นแต่ พวก Core I ที่เป็นสินค้าของ Intel ที่ผมทำไว้ใน ชีท Data CPU
และก็ไม่มี ค่าที่ซ้ำกัน ปรากฎขึ้นครับ
คอลัมน์ D จะเป็นการดึงข้อมูล จาก B และ C มาแล้ว จะปรากฎแค่ค่าของ Series ที่มี แค่ รุ่นนั้น
เช่นผมเลือก คอลัมน์ B ผมเลือก AMD / คอลัมน์ C ผมเลือก Ryzen 5 / คอลัมน์ D จะปรากฎแค่ CPU ที่อยู่ใน Series AMD Ryzen 5 เท่านั้น ครับ แต่ตอนนี่ ปรากฎ ทุกอันเลยครับ
Re: Drop Down List ไม่ให้โชว์ตัวซ้ำกัน และ ให้ Drop Down List เป็นชั้นๆ ต้องทำยังไง ครับ
Posted: Mon Sep 21, 2020 9:08 am
by xsilver
รูป ประกอบครับ
Re: Drop Down List ไม่ให้โชว์ตัวซ้ำกัน และ ให้ Drop Down List เป็นชั้นๆ ต้องทำยังไง ครับ
Posted: Mon Sep 21, 2020 1:46 pm
by puriwutpokin
ที่ ชีท Data CPU ทำตามไฟล์แนนครับ
ที่ ชีท Data CPU K2:P2=IFERROR(INDEX($B2:$B99,MATCH(0,INDEX(COUNTIF($J2:J2,$B2:$B99),),))&"","")
ที่ ชีท Data CPU K3:P20=IFERROR(INDEX($C$2:$C$99,MATCH(0,IF($B$2:$B$99=K$2,COUNTIF(K$2:K2,$C$2:$C$99)),))&"","") กด Ctrl+Shift+Enter
ที่ ชีท SPEC ที่คอลัมน์ B ที่ Validation ใส่ =OFFSET('Data CPU'!$K$2,,,1,COUNTIF('Data CPU'!$K$2:$P$2,"?*"))
ที่ ชีท SPEC ที่คอลัมน์ C ที่ Validation ใส่=OFFSET('Data CPU'!$K$3,,MATCH($B2,'Data CPU'!$K$2:$P$2,)-1,COUNTIF(INDEX('Data CPU'!$K$3:$P$20,,MATCH($B2,'Data CPU'!$K$2:$P$2,)),"?*"),1)
ที่ ชีท SPEC ที่คอลัมน์ D ที่ Validation ใส่=OFFSET('Data CPU'!$D$2,MATCH($C2,'Data CPU'!$C$2:$C$99,)-1,,COUNTIF('Data CPU'!$C$2:$C$99,$C2),1)
ที่ ชีท SPEC E2=IFERROR(INDEX('Data CPU'!$I$2:$I$99,MATCH(D2,'Data CPU'!$D$2:$D$99,),),"")
Re: Drop Down List ไม่ให้โชว์ตัวซ้ำกัน และ ให้ Drop Down List เป็นชั้นๆ ต้องทำยังไง ครับ
Posted: Tue Sep 22, 2020 11:31 am
by xsilver
puriwutpokin wrote: Mon Sep 21, 2020 1:46 pm
ที่ ชีท Data CPU ทำตามไฟล์แนนครับ
ที่ ชีท Data CPU K2:P2=IFERROR(INDEX($B2:$B99,MATCH(0,INDEX(COUNTIF($J2:J2,$B2:$B99),),))&"","")
ที่ ชีท Data CPU K3:P20=IFERROR(INDEX($C$2:$C$99,MATCH(0,IF($B$2:$B$99=K$2,COUNTIF(K$2:K2,$C$2:$C$99)),))&"","") กด Ctrl+Shift+Enter
ที่ ชีท SPEC ที่คอลัมน์ B ที่ Validation ใส่ =OFFSET('Data CPU'!$K$2,,,1,COUNTIF('Data CPU'!$K$2:$P$2,"?*"))
ที่ ชีท SPEC ที่คอลัมน์ C ที่ Validation ใส่=OFFSET('Data CPU'!$K$3,,MATCH($B2,'Data CPU'!$K$2:$P$2,)-1,COUNTIF(INDEX('Data CPU'!$K$3:$P$20,,MATCH($B2,'Data CPU'!$K$2:$P$2,)),"?*"),1)
ที่ ชีท SPEC ที่คอลัมน์ D ที่ Validation ใส่=OFFSET('Data CPU'!$D$2,MATCH($C2,'Data CPU'!$C$2:$C$99,)-1,,COUNTIF('Data CPU'!$C$2:$C$99,$C2),1)
ที่ ชีท SPEC E2=IFERROR(INDEX('Data CPU'!$I$2:$I$99,MATCH(D2,'Data CPU'!$D$2:$D$99,),),"")
ขอบคุณครับ