Snasui Excel Forum

สวัสดีค่ะ
รบกวนผู้รู้ทุกท่าน ช่วยสร้างสูตรสำหรับใช้ประเมินผลการปฏิบัติงานประจำปี ซึ่งเดิมมีการใช้งานมาประมาณ 3 ปี ปีปัจจุบันมีการปรับอัตราเปอร์เซ็นต์ในการปรับเงินเดือนและโบนัส ซึ่ง จขกท.มีความรู้ไม่มากในการสร้างสูตร จึงตั้งกระทู้นี้มา เพื่อรบกวนผู้รู้ทุกท่านช่วย จขกท.หน่อยค่ะ
รายละเอียดตามไฟล์ excel ที่แนบให้ค่ะ หากสงสัยตรงไหน สอบถามได้เลยค่ะ ขอขอบพระคุณผู้รู้ทุกท่านค่ะ

B7
=IF(B5<=18000,2,1)

B6
=IF(B5>18000,
IF(B4>=1,
IF(B3="A",5%,(IF(B3="B",3%,(IF(B3="C",2%,0))))),
IF(B4>=0.5,
IF(B3="A",2%,(IF(B3="B",1%,(IF(B3="C",0.5%,0))))),0)),
IF(B5<=18000,
IF(B4>=1,
IF(B3="A",6%,(IF(B3="B",5%,(IF(B3="C",3%,0))))),
IF(B4>=0.5,
IF(B3="A",3%,(IF(B3="B",2%,(IF(B3="C",1%,0))))),0))))

B12
=IF(B4>=1,
IF(B3="A",1,IF(B3="B",0.7,(IF(B3="C",0.5,0)))),
IF(B4>=0.5,
IF(B3="A",0.5,(IF(B3="B",0.3,(IF(B3="C",0.2,0)))))))

เบื้องต้น ต้องขอบคุณ คุณ parakorn ที่มาช่วยสร้างสูตรให้นะคะ

จนขก. ได้ลองนำสูตรไป test พบปัญหาตรงกลุ่มเงินเดือนที่น้อยกว่า 18,000 บาท และ มีอายุงานตั้งแต่ 6 เดือน ถึง 1 ปี แสดงผลเปอร์เซ็นต์ไม่ตรงตามที่ จขกท.เข้าใจ เพราะว่า เงื่อนไขการปรับเปอร์เซ็นต์ของกลุ่มดังกล่าว จะอิงอายุงานด้วย คือ อายุงานมากกว่าหรือเท่ากับ 6 เดือน แต่ไม่ถึง 1 ปี จะได้รับการพิจารณาปรับเงินเดือน 50% ของอัตราที่ได้รับการประเมิน เช่น พนักงาน อายุงาน 6 เดือน ได้เกรดประเมิน A ได้รับเงินเดือน 10,000 บาท แบบนี้ ตามเงื่อนไข พนักงานต้องได้รับเปอร์เซ็นต์การปรับ = 1.5% แต่สูตรที่ คุณ parakorn สร้างมาให้นั้น พนักงานกลับได้รับเปอร์เซ็นต์การปรับ = 3%

รบกวน คุณ parakorn ช่วยดูสูตรให้อีกครั้งได้ไหมคะ

ขอขอบคุณล่วงหน้าค่ะ

parakorn wrote: Mon Dec 14, 2020 4:09 pm B7
=IF(B5<=18000,2,1)

B6
=IF(B5>18000,
IF(B4>=1,
IF(B3="A",5%,(IF(B3="B",3%,(IF(B3="C",2%,0))))),
IF(B4>=0.5,
IF(B3="A",2%,(IF(B3="B",1%,(IF(B3="C",0.5%,0))))),0)),
IF(B5<=18000,
IF(B4>=1,
IF(B3="A",6%,(IF(B3="B",5%,(IF(B3="C",3%,0))))),
IF(B4>=0.5,
IF(B3="A",3%,(IF(B3="B",2%,(IF(B3="C",1%,0))))),0))))

B12
=IF(B4>=1,
IF(B3="A",1,IF(B3="B",0.7,(IF(B3="C",0.5,0)))),
IF(B4>=0.5,
IF(B3="A",0.5,(IF(B3="B",0.3,(IF(B3="C",0.2,0)))))))

จากตารางที่แนบมากำหนดปรับที่ 3%
แล้วมีเงื่อนไขใดที่จะทำให้ปรับ 3% ตามตาราง
และ เงื่อนไขไหนที่ทำให้ลดลง 50% จากเรทบ้างครับ

B9
=IFERROR(INDEX(CHOOSE(1+(B5>18000),{3,6;2,5;1,3},{2,5;1,3;0.5,2}),MATCH(B3,{"A";"B";"C"},),MATCH(B4,{0.5,1})),0)%*LOOKUP(B4,{0;0.5;1;3;6;10},{0;0.5;1;1.05;1.1;1.15})

B12
=N(VLOOKUP(B3,{"A",0.5,1;"B",0.3,0.7;"C",0.2,0.5;"D",0,0},MATCH(B4,{0,0.5,1})))

จากไฟล์แนบ จขกท.มีระบุเงื่อไขเพิ่มเติมด้านล่างไว้ด้วยน่ะค่ะ ตรงส่วน "ขั้นตอนและวิธีการพิจารณาปรับเงินเดือน > ข้อ 2. อายุงาน > ข้อย่อย 2. อายุงานมากกว่าหรือเท่ากับ 6 เดือน แต่ไม่ถึง 1 ปี จะได้รับการพิจารณาปรับเงินเดือน 50% ของอัตราที่ได้รับการประเมิน" ค่ะ

parakorn wrote: Mon Dec 14, 2020 5:58 pm จากตารางที่แนบมากำหนดปรับที่ 3%
แล้วมีเงื่อนไขใดที่จะทำให้ปรับ 3% ตามตาราง
และ เงื่อนไขไหนที่ทำให้ลดลง 50% จากเรทบ้างครับ

ขอบคุณ คุณ Bo_ry มากค่ะ จขกท.ลอง test ใช้งาน พบว่าสูตรใช้งานตอบโจทย์ได้ค่ะ

Bo_ry wrote: Mon Dec 14, 2020 9:02 pm B9
=IFERROR(INDEX(CHOOSE(1+(B5>18000),{3,6;2,5;1,3},{2,5;1,3;0.5,2}),MATCH(B3,{"A";"B";"C"},),MATCH(B4,{0.5,1})),0)%*LOOKUP(B4,{0;0.5;1;3;6;10},{0;0.5;1;1.05;1.1;1.15})

B12
=N(VLOOKUP(B3,{"A",0.5,1;"B",0.3,0.7;"C",0.2,0.5;"D",0,0},MATCH(B4,{0,0.5,1})))

จขกท. ต้องขอขอบคุณผู้รู้ทั้งสองท่านมากเลยนะคะ คุณ parakorn และ คุณ Bo_ry ที่มาช่วยสร้างสูตรขั้นเทพให้กับ จขกท.