Page 1 of 1
แสดงข้อมูลที่ซ้ำกันเพียง 1 ข้อมูล
Posted: Sun Feb 21, 2021 8:44 pm
by kajonpor
รบกวนด้วยนะคะ
ต้องการกรองข้อมูลที่ซ้ำกัน โดยให้แสดงเพียง 1 ข้อมูล
เช่น พนักงานรหัส A มี FAC และ STD อะไรบ้าง
Re: แสดงข้อมูลที่ซ้ำกันเพียง 1 ข้อมูล
Posted: Sun Feb 21, 2021 9:37 pm
by puriwutpokin
ต้องใช้ คอลัมน์ช่วยนะครับที่
M3=IFERROR(LOOKUP(2,1/(B$2:B2=B3),M$2:M2)&" | ","")&K3
์์N3=IF(L2=L3,L3,IFERROR(LOOKUP(2,1/(B$2:B2=B3),N$2:N2)&" | ","")&L3) ทั้งหมดคัดลอกลงถึง บรรทัด10
B17=IFERROR(INDEX(B$3:B$10,AGGREGATE(15,6,(ROW(B$3:B$10)-ROW(B$3)+1)/(FREQUENCY(MATCH(B$3:B$10,B$3:B$10,0),ROW(B$3:B$10)-ROW(B$3)+1)>0),ROWS(B$17:B17))),"") Copy down
C17=LOOKUP(2,1/($B$3:$B$10=$B17),M$3:M$10) Copy right and down
Re: แสดงข้อมูลที่ซ้ำกันเพียง 1 ข้อมูล
Posted: Mon Feb 22, 2021 11:33 am
by kajonpor
ขอบคุณมากนะคะ คุณpuriwutpokin
Re: แสดงข้อมูลที่ซ้ำกันเพียง 1 ข้อมูล
Posted: Fri Feb 26, 2021 10:41 am
by kajonpor
จากหัวข้อเดิม รบกวนสอบถามเพิ่มเติมนะคะ
กรณีข้อมูลไม่เรียงกัน ข้อมูลในช่อง STD ต้องแก้ไขสูตรอย่างไร ให้แสดงผลที่ถูกต้องคะ
รบกวนด้วยนะคะ
Re: แสดงข้อมูลที่ซ้ำกันเพียง 1 ข้อมูล
Posted: Fri Feb 26, 2021 11:21 am
by puriwutpokin
แก้ N3=IF(L3=L4,L3,IFERROR(LOOKUP(2,1/(B$2:B2=B3),N$2:N2)&" | ","")&L3)
Re: แสดงข้อมูลที่ซ้ำกันเพียง 1 ข้อมูล
Posted: Fri Feb 26, 2021 12:07 pm
by norkaz
ถ้ายังใช้ CONCAT ได้
C17
=MID(CONCAT(IFERROR(IF(MATCH($B17&K$3:K$10,$B$3:$B$10&K$3:K$10,0)=ROW($B$3:$B$10)-2," | "&K$3:K$10,""),"")),4,99)
Ctrl + Shift + Enter
Copy ไปขวา
Norkaz
Re: แสดงข้อมูลที่ซ้ำกันเพียง 1 ข้อมูล
Posted: Fri Feb 26, 2021 12:21 pm
by norkaz
ถ้าใช้ CONCAT ได้
ไหนๆก็เขียนมาแบบบังคับใช้ IFERROR ไปแล้ว ค่า ROW ไปเริ่มที่แถวที่ 1 เลย ไม่ต้องบังคับค่าแถวเป็นอย่างอื่นอีก
C17
=MID(CONCAT(IFERROR(IF(MATCH($B17&K$3:K$10,$B$3:$B$10&K$3:K$10,0)=ROW($B$1:$B$10)," | "&K$3:K$10,""),"")),4,99)
Ctrl + Shfit +Enter
Copy ไปขวา
Norkaz
Re: แสดงข้อมูลที่ซ้ำกันเพียง 1 ข้อมูล
Posted: Fri Feb 26, 2021 12:22 pm
by kajonpor
