Page 1 of 1
สูตรดึงข้อมูลพร้อมบวกค่าค่ะ
Posted: Fri Oct 30, 2015 11:28 am
by suka
เรียนอาจารย์และท่านผู้รู้ค่ะ
ขอรบกวนช่วยเรื่องสูตรการดึงข้อมูล จากตัวอย่างไฟล์แนบคอลัมน์ C:G ดึงมาวางที่คอลัมน์ I:M
เงื่อนไขค่าในเซลล์ C2:C7 หากมีค่าตรงกับค่าในเซลล์ A2:A8 ให้ดึงข้อมูลที่ตรงกันมาไว้ที่เซลล์ I2:M7
รหัสในคอลัมน์ C มีค่าตรงกับคอลัมน์ A ก็ให้ดึงรหัสนั้นมาวางที่เซล์ I2 ตามด้วยค่าในเซลล์ถัดไปมาวางด้วยค่ะ
แต่หากรหัสเดียวกันในคอลัมน์ C มีค่าตรงกับค่าในคอลัมน์ A มากกว่า 1 ให้ดึงมาแค่ 1 และนำจำนวนจากรหัสเดียวกันมาบวกกัน ตามตัวอย่างในเซลล์ J3 และ M3 ค่ะ
Re: สูตรดึงข้อมูลพร้อมบวกค่าค่ะ
Posted: Fri Oct 30, 2015 5:54 pm
by DhitiBank
ขอถามเพิ่มครับ ในตาราง
สีฟ้า มีโอกาสที่รหัสเดียวกันจะมีหน่วยไม่เหมือนกันไหมครับ
หากมี จะต้องแยกออกมาคนละแถวใช่ไหมครับ
Re: สูตรดึงข้อมูลพร้อมบวกค่าค่ะ
Posted: Fri Oct 30, 2015 6:12 pm
by suka
รหัสเดียวกันใช้หน่วยหมือนกันค่ะ
Re: สูตรดึงข้อมูลพร้อมบวกค่าค่ะ
Posted: Fri Oct 30, 2015 7:15 pm
by DhitiBank
ลองแบบนี้ครับ
ที่ I2 คีย์
=IFERROR(INDEX($A$2:$A$8,SMALL(IF(COUNTIF($C$2:$C$7,$A$2:$A$8),ROW($A$2:$A$8)-ROW($A$2)+1),ROWS(I$2:I2)),""))
Ctrl+Shift+Enter
ที่ J2 คีย์
=IF(I2="","",SUMIF($C$2:$C$7,I2,$D$2:$D$7))
enter
ที่ K2 คีย์
=IF($I2="","",INDEX(E$2:E$7,MATCH($I2,$C$2:$C$7,0)))
enter --> คัดลอกไป L2
ที่ M2 คีย์
=IF(I2="","",J2*L2)
enter
แล้วคัดลอกสูตรทั้งหมดลงล่างครับ
Re: สูตรดึงข้อมูลพร้อมบวกค่าค่ะ
Posted: Sat Oct 31, 2015 9:05 am
by suka
ขอบคุณค่ะคุณ DhitiBank ที่เซลล์ i2 วางสูตรไม่ได้ค่ะ ขึ้นข้อความตามรูปแนบค่ะ
Re: สูตรดึงข้อมูลพร้อมบวกค่าค่ะ
Posted: Sat Oct 31, 2015 10:04 am
by snasui
ตัวอย่างสูตรครับ
เซลล์ I2 คีย์
=IFERROR(INDEX(C$2:C$7,SMALL(IF(FREQUENCY(IF(ISNUMBER(MATCH($C$2:$C$7,$A$2:$A$8,0)),MATCH($C$2:$C$7,$C$2:$C$74,0)),ROW($C$2:$C$7)-ROW($C$2)+1),ROW($C$2:$C$7)-ROW($C$2)+1),ROWS(I$2:I2))),"")
Ctrl+Shift+Enter > Copy ลงด้านล่าง
สูตรที่เหลือสามารถใช้ตามที่คุณ DhitiBank ตอบไว้แล้วได้ หากติดตรงไหนค่อยมาถามกันต่อครับ
Re: สูตรดึงข้อมูลพร้อมบวกค่าค่ะ
Posted: Sat Oct 31, 2015 11:21 am
by suka
ขอบคุณอาจารย์ และคุณ DhitiBank มากค่ะ
เซลล์ J2 และเซลล์ M2 ใช้สูตรคุณ DhitiBank ได้สูตรตรงตามที่ต้องการค่ะ
ที่เซลล์ J2 คีย์
=IF(I2="","",SUMIF($C$2:$C$7,I2,$D$2:$D$7))
ที่เซลล์ M2 คีย์
=IF(I2="","",SUMIF($C$2:$C$7,I2,$G$2:$G$7))
Re: สูตรดึงข้อมูลพร้อมบวกค่าค่ะ
Posted: Sat Oct 31, 2015 12:34 pm
by DhitiBank
ขออภัยครับ คราวหน้าจะทดสอบให้ชัวร์ก่อนค่อยตอบครับ สงสัยจะตาลาย ดึกมาหลายคืน
Re: สูตรดึงข้อมูลพร้อมบวกค่าค่ะ
Posted: Sat Oct 31, 2015 12:44 pm
by snasui
ไม่เป็นไรเลยครับ แค่มีน้ำใจมาตอบปัญหาให้กับเพื่อนสมาชิกก็เป็นความกรุณามากมายแล้ว
สูตรที่ตอบมานั้นใช้งานได้กับตัวอย่างข้อมูลที่ให้มาแค่ติดเรื่องวงเล็บเท่านั้น ผมเองก็มักจะผิดพลาดเรื่องการปิดวงเล็บอยู่ประปราย ถือเป็นเรื่องปกติที่จะผิดกันได้ครับ
ที่ผมตอบไป ได้เพิ่มความสามารถให้เผื่อไปถึงการซ้ำกันของข้อมูลของทั้งสองฝั่ง และปกติผมจะช่วยดูในทุก ๆ กระทู้อยู่แล้วสบายใจได้เลยครับ
Re: สูตรดึงข้อมูลพร้อมบวกค่าค่ะ
Posted: Sat Oct 31, 2015 2:14 pm
by DhitiBank
ขอบคุณอาจารย์มากครับ