Snasui Excel Forum

คอลัมน์ที่บวกกันแล้วเกิน 10 ให้ทดจำนวนสิบ ไปยังเซลซ้ายมือ เหมือนกับวิธีบวกเลขธรรมดา ทำอย่างไรครับ



6+8 = 14 / ใส่ 4 ทด 1 ไปข้างหน้า
9+4 = 13 / ทด 1 เป็น 14 / ใส่ 4 ทด 1 ไปข้างหน้า
8+1 = 9 / ทด 1 เป็น 10 / ใส่ 0 ทด 1 ไปข้างหน้า
5+0 = 5 / ทด 1 เป็น 6

ลักษณะนี้แหละครับ
ขอบคุณมาก

ที่ A3 ลองคีย์

=MOD(INT((SUMPRODUCT($A$1:$E$1,10^(COLUMNS($A$1:$E$1)-(COLUMN($A$1:$E$1)-COLUMN($A$1))))+SUMPRODUCT($A$2:$E$2,10^(COLUMNS($A$1:$E$1)-(COLUMN($A$1:$E$1)-COLUMN($A$1)))))/10^COLUMNS(A1:$E1)),10)

Enter --> คัดลอกไปทางขวาครับ

A3=MOD(SUM(A1:A2,IF(OR(SUM(B1:B2)>=10,SUM(C1:C2)>=10),1,0)),10)

ใช้การเชื่อมเซลล์มาช่วยครับ

=mid(a1&b1&c1&d1&e1+a2&b2&c2&d2&e2,columns($a3:a3),1)

Enter แล้วคัดลอกไปทางขวา

ขอบคุณครับ ทำได้แล้ว
แต่ของคุณ logic ทำแล้วมันออกมาแบบนี้น่ะครับ

ลองปรับเป็นด้านล่างดูครับ

=mid((a1&b1&c1&d1&e1)+(a2&b2&c2&d2&e2),columns($a3:a3),1)

ที่คุณ logic บอกมาใหม่ เมื่อ Fill>Right ไปถึง E3 จะได้ผลลัพท์แค่ 3 คอลัมน์ครับ
เซล D3 กับ E3 ไม่มีค่าใดๆ เกิดขึ้น
แต่เมื่อคลิกที่เซล มันจะขึ้นสูตรแบบนี้ครับ
D3 - - =MID((D1&E1&F1&G1&H1)+(D2&E2&F2&G2&H2),COLUMNS($A3:D3),1)
E3 - - =MID((E1&F1&G1&H1&I1)+(E2&F2&G2&H2&I2),COLUMNS($A3:E3),1)
ผิดพลาดตรงไหนหรือเปล่าครับ ต้องรบกวนอีกละครับ

ต้องล็อคเซลล์ด้วยครับ

=mid(($a1&$b1&$c1&$d1&$e1)+($a2&$b2&$c2&$d2&$e2),columns($a3:a3),1)

อีกตัวอย่างครับ

เซลล์ A3 คีย์

=MOD(SUM(A1:A2)+INT(SUM(B1:B2)/10),10)

Enter > Copy ไปทางขวา

ขอแก้ไขสูตรครับ สูตรเดิมของผมข้างบนใช้ได้ไม่สมบูรณ์
จากเดิม
A3=MOD(SUM(A1:A2,IF(OR(SUM(B1:B2)>=10,SUM(C1:C2)>=10),1,0)),10)
ให้เปลี่ยนเป็น
A3=MOD(SUM(A1:A2,IF(SUM(B1:$E2)>=(9*COLUMNS(B1:$E2)+1),1,0)),10)

Test pattern :
8 9 9 9 9
0 0 0 0 1
----------
9 0 0 0 0

snasui wrote: อีกตัวอย่างครับ

เซลล์ A3 คีย์

=MOD(SUM(A1:A2)+INT(SUM(B1:B2)/10),10)

Enter > Copy ไปทางขวา

สูตรด้านบนนี้ไม่ครอบคลุมทุกกรณี ตัวอย่างสูตรแบบอื่นตามด้านล่างครับ

เซลล์ A3 คีย์

=MID(SUMPRODUCT(($A$1:$E$1+$A$2:$E$2)*(10^(6-COLUMN($A$1:$E$1))))/10,COLUMNS($A3:A3),1)+0

Enter > Copy ไปทางขวา