Page 1 of 1
การรันวันที่แบบต่อเนื่อง
Posted: Thu Nov 21, 2019 1:48 pm
by jThan
ขอทราบสูตรในการกำหนดให้แถวที่ 1 รันวันที่ในรูปแบบดังตัวอย่างสีแดงใน Sheet Result
และหากไม่มีข้อมูลใน Sheet Raw Data ก็ให้เป็นช่องว่าง
ตามไฟล์แนบ Sheet Raw Data ถูกดึงข้อมูลมาจัดเรียงใหม่ตามรูปแบบใน Sheet Result
Result 21_11_19.xls
Re: การรันวันที่แบบต่อเนื่อง
Posted: Thu Nov 21, 2019 4:05 pm
by parakorn
insert แถวบนสุดขึ้นมา 1 แถว
C1 ใส่ =DATE(2019,10,30)
F1 =C1+1 คลุม F1 ถึง H1 Copy ตั้งแต่ I1 ไปทางขวา จนสุดตาราง
C2 =IF(C4="","",TEXT(C1,"mmm dd")&" - "&IF(TEXT(C1,"mmm")<>TEXT(C1+1,"mmm"),TEXT(C1+1,"mmm dd, yy"),TEXT(C1+1,"dd, yy"))) Enter+Copy ไปทางขวา
Re: การรันวันที่แบบต่อเนื่อง
Posted: Thu Nov 21, 2019 4:18 pm
by Bo_ry
C1:W1
=IFERROR(TEXT(INDEX('Raw Data'!$A$2:$A$999,(COLUMNS($C1:C1)+2)*8)-1,"mmm d - ")&TEXT(INDEX('Raw Data'!$A$2:$A$999,(COLUMNS($C1:C1)+2)*8),REPT("mmm",DAY(INDEX('Raw Data'!$A$2:$A$999,(COLUMNS($C1:C1)+2)*8))=1)&"d, y"),"")
B3:B26
=TEXT(MOD(10+ROWS(B$3:B3),24),"00")&":00 - "&TEXT(MOD(11+ROWS(B$3:B3),24),"00")&":00"
C3:W26
=IF(INDEX($C$1:C$1,FLOOR(COLUMNS($C3:C3)-1,3)+1)="","",INDEX('Raw Data'!$C$2:$E$999,ROWS(C$3:C3)+INT((COLUMNS($C3:C3)-1)/3)*24,MOD(COLUMNS($C3:C3)-1,3)+1))
Re: การรันวันที่แบบต่อเนื่อง
Posted: Fri Nov 22, 2019 1:57 pm
by jThan
Bo_ry wrote: Thu Nov 21, 2019 4:18 pm
C1:W1
=IFERROR(TEXT(INDEX('Raw Data'!$A$2:$A$999,(COLUMNS($C1:C1)+2)*8)-1,"mmm d - ")&TEXT(INDEX('Raw Data'!$A$2:$A$999,(COLUMNS($C1:C1)+2)*8),REPT("mmm",DAY(INDEX('Raw Data'!$A$2:$A$999,(COLUMNS($C1:C1)+2)*8))=1)&"d, y"),"")
B3:B26
=TEXT(MOD(10+ROWS(B$3:B3),24),"00")&":00 - "&TEXT(MOD(11+ROWS(B$3:B3),24),"00")&":00"
C3:W26
=IF(INDEX($C$1:C$1,FLOOR(COLUMNS($C3:C3)-1,3)+1)="","",INDEX('Raw Data'!$C$2:$E$999,ROWS(C$3:C3)+INT((COLUMNS($C3:C3)-1)/3)*24,MOD(COLUMNS($C3:C3)-1,3)+1))
ขอบคุณค่ะ ได้ข้อมูลตามที่ต้องการแล้ว แต่ขอสอบถามเพิ่มเติม
1.ช่อง C1:W1 หากมีการเพิ่มชีทดึงข้อมูลที่มีลักษณะคล้ายกัน แต่ดึงเพียง 2 คอลัมน์ (C1:P1) หรือเพิ่มข้อมูลแล้วดึงมากขึ้นเป็น 6 คอลัมน์ (C1:AR1) จะต้องปรับเปลี่ยนตรงไหนบ้างคะ
2.สามารถกำหนดให้เดือนเป็นภาษาอังกฤษเฉพาะไฟล์นี้ได้หรือไม่ โดยที่ไม่ต้องไปแก้ที่ Region and Language เพราะบางไฟล์ยังต้องการให้เป็นภาษาไทย (บางเครื่องแสดงเป็น ต.ค. 30 - 31, 19)
Re: การรันวันที่แบบต่อเนื่อง
Posted: Fri Nov 22, 2019 2:46 pm
by Bo_ry
1. C1
=IFERROR(TEXT(INDEX('Raw Data'!$A$2:$A$999,(COLUMNS($C1:C1)+1)*12)-1,"[$-en]mmm d - ")&TEXT(INDEX('Raw Data'!$A$2:$A$999,(COLUMNS($C1:C1)+1)*12),REPT("[$-en]mmm",DAY(INDEX('Raw Data'!$A$2:$A$999,(COLUMNS($C1:C1)+1)*12))=1)&"d, y"),"")
2. C1
=IFERROR(TEXT(INDEX('Raw Data'!$A$2:$A$999,(COLUMNS($C1:C1)+2)*8)-1,"[$-en]mmm d - ")&TEXT(INDEX('Raw Data'!$A$2:$A$999,(COLUMNS($C1:C1)+2)*8),REPT("[$-en]mmm",DAY(INDEX('Raw Data'!$A$2:$A$999,(COLUMNS($C1:C1)+2)*8))=1)&"d, y"),"")
Re: การรันวันที่แบบต่อเนื่อง
Posted: Fri Nov 22, 2019 5:27 pm
by jThan
ขอบคุณมากค่ะ ได้ตามต้องการเลย
แล้วก็พอจะเข้าใจหลักการของสูตรที่คุณเขียนให้แล้วค่ะ
เป็นประโยชน์ในการนำไปใช้กับไฟล์อื่นๆ ด้วย