Snasui Excel Forum

ขออนุญาตสอบถามการกรองตัวเลข ip ที่ไม่มีรูปแบบที่ตายตัว และอยู่ในกลุ่มที่ไม่มีรูปแบบใดๆเลยครับ
โดยต้องการใช้สูตร ซึ่งผมลองใช้ find, mid, len , if ต่างๆจนไม่สามารถแยกออกมาจากกลุ่มประโยคได้ครับ
จึงขอความกรุณาด้วยครับ และพร้อมกับแนบไฟล์มาด้วยครับ ขอขอบคุณมากๆครับ

กรุณา Update Version ของ Excel ที่ใช้ตามตัวอย่างใน Link นี้ด้วยครับ https://snasui.com/viewtopic.php?f=6&p=103177#p103177

ตัวอย่างสูตรตามด้านล่างครับ

1. ที่ C1:J1 คีย์หัวคอลัมน์เป็น IP_Last_Position, IP_First_Position, Str_Contain_IP, Num_Pre_Dot, Chr_Pre_Dot, Chr_Post_Dot Replace_Pre, Replace_Post_(Result) ตามลำดับ
2. ที่ C2 คีย์
   =FIND(".",A2,FIND("@",SUBSTITUTE(A2,".","@",LEN(A2)-LEN(SUBSTITUTE(A2,".","")))))+4
   Enter > Copy ลงด้านล่าง
3. ที่ D2 คีย์
   =C2-15
   Enter > Copy ลงด้านล่าง
   เลข 15 คือจำนวนอักขระของ IP ที่จะมีได้ทั้งหมด เช่น 255.255.255.255
4. ที่ E2 คีย์
   =MID(A2,D2,15)
   Enter > Copy ลงด้านล่าง
5. ที่ F2 คีย์
   =FIND(".",E2)-1
   Enter > Copy ลงด้านล่าง
6. ที่ G2 คีย์
   =LOOKUP(999,--MID(SUBSTITUTE(E2,":","|"),F2-ROW(INDIRECT("1:"&F2))+1,ROW(INDIRECT("1:"&F2))))
   Enter > Copy ลงด้านล่าง
7. ที่ H2 คีย์
   =LOOKUP(999,--MID(RIGHT(SUBSTITUTE(E2,".",REPT(" ",5)),3),1,{1,2,3}))
   Enter > Copy ลงด้านล่าง
8. ที่ I2 คีย์
   =REPLACE(E2,1,F2,G2)
   Enter > Copy ลงด้านล่าง
9. ที่ J2 คีย์
   =REPLACE(I2,FIND("@",SUBSTITUTE(I2,".","@",3))+1,3,H2)
   Enter > Copy ลงด้านล่าง

อีกแบบ
B2
=-LOOKUP(1,-MID(A2,MIN(SEARCH({".?.",".??.",".???."},A2&"....."))-{1,2,3},{1,2,3}))&"."&SUBSTITUTE(TRIM(LEFT(RIGHT(SUBSTITUTE(A2,".",REPT(" ",40)),120),80))," ",".")&"."&-LOOKUP(1,-LEFT(TRIM(RIGHT(SUBSTITUTE(A2,".",REPT(" ",20)),20)),{1,2,3}))

ขอขอบพระคุณอย่างสูงครับ​ เพิ่งกลับถึงบ้านครับ​ จะลองทดสอบดูครับ