มีปัญหาในการ run code ค่ะ ลองดูให้หน่อยนะคะ

[tantanz]

เกิดปัญหาในการรันค่ะ มันขึ้น run time error 1004 ไม่ทราบว่าเป็นเพราะสาเหตุใดคะ แล้วมีวิธีการแก้ไขอย่างไรบ้าง

Public Sub Drawlayout()
Dim i As Integer
Dim no_c As Single 'number of customer
Dim nb() As Integer 'หมายเลขเครื่อง
Dim mc() As String 'ชื่อเครื่องจักร
Dim rowstart() As Integer 'rowเริ่มต้น
Dim columstart() As Integer 'columเริ่มต้น
Dim rowend() As Integer 'rowจบ
Dim columend() As Integer 'columจบ

i = 3
no_c = 0
Do Until Worksheets("Data").Cells(i, 1).Value = ""

i = i + 1
no_c = no_c + 1

Loop
ReDim nb(1 To no_c)
ReDim mc(1 To no_c)
ReDim rowstart(1 To no_c)
ReDim columstart(1 To no_c)
ReDim rowend(1 To no_c)
ReDim columend(1 To no_c)

i = 1
For i = 1 To no_c
nb(i) = Worksheets("Data").Cells(i + 2, 1).Value 'หมายเลขเครื่อง
mc(i) = Worksheets("Data").Cells(i + 2, 2).Value 'ชื่อเครื่องจักร
rowstart(i) = Worksheets("Data").Cells(i + 2, 3).Value 'rowเริ่มต้น
columstart(i) = Worksheets("Data").Cells(i + 2, 4).Value 'columเริ่มต้น
rowend(i) = Worksheets("Data").Cells(i + 2, 5).Value 'rowจบ
columend(i) = Worksheets("Data").Cells(i + 2, 6).Value 'columจบ

Next i

Dim a As Integer, b As Integer, z As Integer, y As Integer
Dim start As String
Dim C_end As String


i = 1
For i = 1 To no_c

a = rowstart(i)
b = columstart(i)
y = rowend(i)
z = columend(i)


Worksheets("Plant").Range(Cells(a, b), Cells(y, z)).Value = i

Next i

End Sub

[snasui]

แนบไฟล์ตัวอย่างมาด้วย ตัดมาเฉพาะ Code และชีทที่เกี่ยวข้องมาก็พอครับ

สำหรับการโพสต์ Code ให้แสดงเป็น Code ดูตัวอย่างทีนี่เพื่อสะดวกต่อการอ่านและ Copy ไปใช้ครับ http://www.snasui.com/viewtopic.php?f=3&t=1187

[bank9597]

ต้องมีไฟล์แนบด้วยครับ พร้อมทั้งแจ้งด้วยว่าติดปัญหาที่แมโครชื่ออะไร

[tantanz]

ติดตรง Module Drawlayout ค่ะ

แนบไฟล์มาแล้วนะคะ

[snasui]

ปรับ Code เป็นตามด้านล่างครับ

Code: Select all

'Other code
With Worksheets("Plant")
    .Range(.Cells(a, b), .Cells(y, z)).Value = i
End With
'Other code

[tantanz]

ได้แล้วค่ะ ขอบคุณมากนะคะ ^^