สอบถามเรื่อง Match หลายเงื่อนไขครับ

[bondham]

จากไฟล์นะครับ
ในชีต Items_min_max ในแถบสีเหลือง ครับผมต้องการคือค่าจาก avg_month
โดยใน sheet Items_Min_Max จะเป็นการหาค่าตัวเลข จาก sheet avg_month โดยให้ match ทั้ง No_ และ เลข หัว column
ในที่นี้คือ 1 , 2, 3 ,4 ..... จาก sheet avg_month และนำค่าจาก avg_month ที่ D:D มาแสดง

จากด้านล่างผมลองเขียนแบบนี้ครับ แต่มันไม่ออกครับ

Code: Select all

=INDEX(AVG_Month!D:D,MATCH(1,INDEX((AVG_Month!$A:$A=Items_Min_Max!$L$1)*(AVG_Month!$B:$B=Items_Min_Max!$A2),0),0),0)

items.jpg

month.jpg

AVG_store.xlsx

[snasui]

ตัวอย่างสูตรครับ

เซลล์ L2 คีย์

=LOOKUP(2,1/(AVG_Month!$A$2:$A$482=--L$1)/(AVG_Month!$B$2:$B$482=$A2),AVG_Month!$D$2:$D$482)

Enter > Copy ไปด้านขวาและลงด้านล่าง

[Bo_ry]

L2
=SUMIFS(AVG_Month!$D$2:$D$482,AVG_Month!$A$2:$A$482,L$1,AVG_Month!$B$2:$B$482,$A2)

หรือจะ
=IFERROR(AVERAGEIFS(AVG_Month!$D$2:$D$482,AVG_Month!$A$2:$A$482,L$1,AVG_Month!$B$2:$B$482,$A2),"")

[Bo_ry]

ขอบคุณ คุณ norkaz ที่ทักมานะครับ
ทักตรงนี้เลยก็ได้นะครับ

ปรับเพิ่ม สำหรับข้อความที่เป็นตัวเลขเกิน 15 หลัก

=SUMIFS(AVG_Month!$D$2:$D$483,AVG_Month!$A$2:$A$483,L$1,AVG_Month!$B$2:$B$483,UNICHAR(888)&$A2)

[bondham]

ขอบคุณอาจารย์ทุกๆท่านมากครับ แต่มีข้อสงสัยครับ จากสูตรที่ผมเขียนขึ้นเพราะอะไรทำไมมันถึงไม่แสดงค่าครับ ทั้งๆที่ก่อนหน้านี้ เคยเอาไปปรับใช้แล้วแสดงผลครับ เพื่อที่ต่อไปจะได้เข้าใจมากขึ้นครับ

สูตร
=INDEX(AVG_Month!D:D,MATCH(1,INDEX((AVG_Month!$A:$A=Items_Min_Max!$L$1)*(AVG_Month!$B:$B=Items_Min_Max!$A2),0),0),0)

[snasui]

ค่านี้ Items_Min_Max!$L$1 จะต้องแปลงเป็นตัวเลขเสียก่อน เช่น บวกด้วย 0 จึงจะนำไปเทียบกับค่าใน AVG_Month!$A:$A ครับ

[bondham]

จากสูตร
=LOOKUP(2,1/(AVG_Month!$A$2:$A$482=--L$1)/(AVG_Month!$B$2:$B$482=$A2),AVG_Month!$D$2:$D$482)


เลข 2 ที่ต่อจาก Lookup คือค่าอะไรครับทำไมถึงเป็น 2 ครับ

[norkaz]

...

เลข 2 LOOKUP ที่อาจารย์ คนควนใช้ ในลักษณะนั้น เพื่อแสดง เลขที่มากกว่า 1

จะใช้เลขอะไรก็ได้ครับที่มากกว่า 1 แต่ปกติ มักนิยมใช้ 2

Norkaz

[snasui]

ทำความเข้าใจกับ Lookup ลักษณะนี้ได้ที่นี่ครับ https://snasui.com/wordpress/last-cell-that-not-blank/