ขอปรึกษาเกี่ยวกับการใช้ Excel สร้าง report อัตโนมัติ

[snasui]

ได้ทำตามคำตอบของคุณ Bo_ry แล้วหรือไม่ ได้ผลลัพธ์เป็นกระการใด ช่วย Update สูตรและแนบไฟล์ล่าสุดพร้อมแสดงตัวอย่างคำตอบที่ถูกต้องมาอีกครั้งครับ

[asawin77]

ขอบคุณครับ สูตรของคุณ Bo_ry เป็นสูตรที่ใช้กับ Column ที่มีสูตรเดิมอยู่แล้วครับ ตอนนี้ผมใช้ไฮไลท์สีฟ้าไว้ที่ Column ที่ต้องการเพิ่มเติมสูตรครับ ที่ Column E ,M,N และ P พร้อมกับค่าที่ถูกต้องตามไฟล์แนบครับ

*** หรือผมเข้าใจผิดรบกวนแนะนำด้วยครับ

[snasui]

ตัวอย่างสูตรตามด้านล่างครับ

1. ที่ E9 คีย์
   =SUMPRODUCT(--(INT(ยอดขาย!$B$2:$B$1000)=LOOKUP(9.99999999999999E+307,$B$9:B9)),--(ISNUMBER(SEARCH(C9,ยอดขาย!$D$2:$D$1000))))
   Enter > Copy ลงด้านล่างไปยังเซลล์ที่เกี่ยวข้อง
2. ที่ N9 คีย์
   =SUMPRODUCT(--(INT(ยอดขาย!$B$2:$B$1000)=LOOKUP(9.99999999999999E+307,$B$9:B9)),--(ISNUMBER(SEARCH(C9,ยอดขาย!$D$2:$D$1000))),--(ISNUMBER(SEARCH("Agent",ยอดขาย!$C$2:$C$1000))),ยอดขาย!$E$2:$E$1000)
   Enter > Copy ลงด้านล่างไปยังเซลล์ที่เกี่ยวข้อง
3. ที่ P9 คีย์
   =SUMPRODUCT(--(INT(ยอดขาย!$B$2:$B$1000)=LOOKUP(9.99999999999999E+307,$B$9:B9)),--(ISNUMBER(SEARCH(C9,ยอดขาย!$D$2:$D$1000))),1-(ISNUMBER(SEARCH("Agent",ยอดขาย!$C$2:$C$1000))),ยอดขาย!$E$2:$E$1000)
   Enter > Copy ลงด้านล่างไปยังเซลล์ที่เกี่ยวข้อง

[asawin77]

ขอบคุณครับ แต่ยังเหลือ
Column M การนับจำนวน PO ยังถูกไม่ทั้งหมดเนื่องจาก เมื่อเพิ่มข้อมูลของวันอื่นๆเข้ามาแล้วจะมีช่องว่างสูตรจะไม่นับ อยากให้สูตรนับช่องว่างรวมเป็นถังกลางครับ
- ประจำส่วนตัว - Agent XX นับเป็นถังส่วนตัว (ถูกแล้ว )
- NEW CUST ,NEW อาหารเสริม renew , หรือชื่ออื่นๆ นับเป็นถังกลาง (นับถูกแล้ว)
- แต่จะมี "ช่องว่าง" สูตรจะไม่นับ อยากให้สูตรนับช่องเซลล์ที่ว่างใน column นี้ รวมเป็นถังกลาง

[asawin77]

ขอโทษครับ column O ครับ ไม่ใช่ column M ตอนนี้ใช้สูตรคุณ Bo_ry ได้ตรงแล้วครับ ขอบคุณมากๆครับอาจารย์

[asawin77]

สวัสดีครับอาจารย์ ตอนนี้มี Update ข้อมูลครับ มีข้อมูล Inbound เพิ่มเข้ามาครับ สูตรยังไม่สามารถดึง Inbound มาแสดงใน report ได้ครับ sheet report column G และ H ส่วนข้อมูลอยู่ sheet ยอดขาย column C ผมไฮไลท์ข้อมูลสีเหลืองไว้ที่ต้องการนำมา Report ครับ ส่วนช่องอื่นๆ ยังใช้ได้ปกติครับ รายละเอียดตามไฟล์แนนบครับ

[snasui]

ตัวอย่างสูตรครับ

ตัวอย่างสูตรตามด้านล่างครับ

1. ที่ G7 ลบวรรคหน้า Inbound ทิ้งไป คือเดิมเป็น Inbound แก้เป็น Inbound
2. ที่ G9 คีย์
   =SUMPRODUCT(--(INT(ยอดขาย!$B$2:$B$983)=LOOKUP(9.99999999999999E+307,$B$9:B9)),--(ISNUMBER(SEARCH(C9,ยอดขาย!$D$2:$D$983))),--(ISNUMBER(SEARCH("*"&G$7,ยอดขาย!$C$2:$C$983))))
   Enter > Copy ไปยังเซลล์ที่เกี่ยวข้อง
3. ที่ H9 คีย์
   =SUMPRODUCT(ยอดขาย!$E$2:$E$983,--(INT(ยอดขาย!$B$2:$B$983)=LOOKUP(9.99999999999999E+307,$B$9:B9)),--(ISNUMBER(SEARCH(C9,ยอดขาย!$D$2:$D$983))),--(ISNUMBER(SEARCH(G$7,ยอดขาย!$C$2:$C$983))))
   Enter > Copy ไปยังเซลล์ที่เกี่ยวข้อง

[asawin77]

อาจารย์ครับ ผมลองทำตามที่บอกว่ามาแล้วแต่ยังไม่ได้ครับ จะแก้ไขดูเองก็ไม่ได้สูตรยากเกินไปสำหรับผมครับ รายละเอียดตามไฟล์แนบครับ

[snasui]

คำตอบที่ถูกต้องในแต่ละเซลล์คือค่าเท่าใดบ้างครับ

คอลัมน์ B ในชีต Report ได้ปรับให้เป็นวันที่ที่ตรงกับที่ระบายสีเหลืองไว้ในคอลัมน์ B ของชีต ยอดขาย แล้วหรือไม่ครับ

[asawin77]

ครับ ขอโทษครับ ผมผิดเองไม่ดูให้ดีรีบกลับบ้าน ได้แล้วนะครับ ขอบคุณมากๆครับ

[asawin77]

อาจารย์ครับ ผมพึ่งเจอติดอยู่นิดหนึ่งครับ คราวนี้เป็น Outbound ตัวเลขรวมของ Outbound นับรวมทั้ง Inbound ยอดรวมเกินมาทำให้ Reportผิดครับ ใน sheet report ที่column E และ F ครับ
*** โดยที่เงื่อนไขคือ ถ้า sheet ยอดขาย column C ไม่มีคำว่า Inbound ให้นับเป็น Outbound รวมช่องว่างด้วยครับ *** ขอบคุณครับ

[snasui]

ตัวอย่างการปรับสูตรตามด้านล่างครับ

1. ที่ E9 คีย์
   =SUMPRODUCT(--(INT(ยอดขาย!$B$2:$B$910)=LOOKUP(9.99999999999999E+307,$B$9:B9)),--(ISNUMBER(SEARCH(C9,ยอดขาย!$D$2:$D$910))),1-ISNUMBER(SEARCH(G$7,ยอดขาย!$C$2:$C$910)))
   Enter > Copy ลงด้านล่างยังเซลล์ที่เกี่ยวข้อง
2. ที่ F9 คีย์
   =SUMPRODUCT(ยอดขาย!$E$2:$E$910,--(INT(ยอดขาย!$B$2:$B$910)=LOOKUP(9.99999999999999E+307,$B$9:B9)),--(ISNUMBER(SEARCH(C9,ยอดขาย!$D$2:$D$910))),1-ISNUMBER(SEARCH(G$7,ยอดขาย!$C$2:$C$910)))
   Enter > Copy ลงด้านล่างยังเซลล์ที่เกี่ยวข้อง

[asawin77]

ขอบคุณครับได้แล้วนะครับ