:D snasui.com ยินดีต้อนรับ :D
ยินดีต้อนรับสู่กระดานถามตอบ Excel and VBA และอื่น ๆ ที่เป็นมิตรกับทุกท่าน มีไฟล์แนบมหาศาล ช่วยให้ท่านค้นหาและติดตามศึกษาได้โดยง่าย :thup: สมาชิกท่านใดที่ยังไม่ได้ระบุ Version ของ Excel ที่ใช้งานจริง สามารถทำตาม Link นี้เพื่อจะได้รับคำตอบที่ตรงกับ Version ของท่านครับ :arrow: ระบุ Version ของ Excel
:!: โปรดทราบ :!:
  1. กรุณาอ่านกฎการใช้บอร์ด (Forum rules) ในตำแหน่งด้านบนของแต่ละบอร์ด
  2. การสมัครสมาชิก การ Login การกู้คืนรหัสผ่าน
    1. สมัครสมาชิกดูขั้นตอนได้ที่ :arrow: สมัครสมาชิก
    2. Login เข้าระบบโดยคลิกปุ่ม Login ตรงมุมขวาบนของหน้านี้ :roll:
    3. การ Login ผ่าน Facebook ดูวิธีที่ :arrow: Login ผ่าน Facebook
    4. ลืมรหัสผ่านสามารถรับรหัสใหม่ได้ที่ :arrow: Reset รหัสผ่าน
  3. มีปัญหาการใช้งาน แจ้งผู้ดูแลระบบได้ที่ :arrow: ติดต่อผู้ดูแลระบบ
  4. กำหนดการตั้งค่าส่วนตัว เช่นตั้งค่าภาษาเป็นไทยหรืออังกฤษดูได้ที่ :arrow: ตั้งค่าส่วนตัว
  5. การตั้งและตอบกระทู้ดูได้ที่ :arrow: วิธีการตั้งและตอบกระทู้
  6. การจัดรูปแบบตัวอักษรด้วย bbcode ในช่องแสดงความคิดเห็นดูได้ที่ :arrow: จัดรูปแบบตัวอักษร
  7. กำหนดขนาดตัวอักษรใน Browser ดูได้ที่ :arrow: กำหนดขนาดตัวอักษรใน Browser
🪷 คำแสดงเจตนา
ขอผลแห่งการให้ความรู้นี้ จงกลับไปยังผู้ที่เป็นเจ้าของเดิม แม้ข้าพเจ้าจะไม่รู้จักท่านก็ตาม ขอให้แสงแห่งปัญญาที่ท่านเคยจุดไว้ ได้กลับไปเติมเต็มชีวิตของท่านอีกครั้ง และขอให้เจตนาของข้าพเจ้าเป็นการคืนความดีอย่างสงบ

ขอสูตรจัดรายชื่อตามรูปแบบที่กำหนดครับ

ฟอรัมถาม-ตอบปัญหาการใช้งาน MS Excel and VBA
Forum rules
  1. ไม่อนุญาตให้ใช้ภาษาแชทในการถามและตอบปัญหา ไม่ใช้คำว่า "คับ" หรือ "อ่ะครับ" แทนคำว่า "ครับ" ไม่ใช้คำว่า "เด๋ว" แทนคำว่า "เดี๋ยว" เป็นต้น เนื่องจากเมื่อแปลเป็นภาษาต่างประเทศแล้วจะให้ความหมายผิดไปจากที่ควรจะเป็น
  2. ห้ามถามโดยระบุชื่อผู้ตอบและต้องตั้งชื่อกระทู้ให้สื่อถึงปัญหาที่จะถาม ไม่ตั้งชื่อว่า ช่วยด้วยครับ, มีปัญหามาปรึกษาครับ เป็นต้น
  3. กรุณาอธิบายปัญหาและระบุคำตอบที่ต้องการมาในกระทู้ด้วยเสมอถึงแม้จะอธิบายไว้ในไฟล์แนบแล้วก็ตาม ทั้งนี้เพื่ออำนวยความสะดวกแก่เพื่อนสมาชิกในการค้นหาข้อมูล
  4. กรุณาแนบไฟล์ตัวอย่างพร้อมแสดงคำตอบที่ถูกต้องมาในไฟล์ด้วยเพื่อให้ง่ายต่อการทำความเข้าใจและสะดวกต่อการตอบคำถาม (ขนาดไฟล์ไม่เกิน 500Kb ขนาดภาพไม่เกิน 800*600 Pixel) ไม่แนบเป็น Link มาจากแหล่งอื่นที่อาจจะถูกลบทิ้งไปโดยต้นทางในภายหลัง นอกจากนี้ไม่ควรแนบไฟล์ที่มีข้อมูลสำคัญอันก่อให้เกิดความเสียหายกับตนเองและผู้อื่น
  5. กรณีเป็นคำถามเกี่ยวกับ Programming เช่น VBA, VB.Net, C#, SQL ฯลฯ ต้องลองเขียนมาเองก่อนเสมอ ถามเฉพาะที่ติดปัญหา ระบุ Module, Procedure ที่ติดปัญหาให้ชัดเจน กรุณาโพสต์ Code ให้แสดงเป็น Code คือเปิดด้วย [code] และปิดด้วย [/code] ตัวอย่างเช่น [code]dim r as range[/code] เพื่อให้แตกต่างจากข้อความทั่วไป สะดวกในการอ่านและทดสอบ (คลิกเพื่อดูตัวอย่าง)
  6. กรุณาแจ้งผลการใช้งานเมื่อได้รับคำตอบว่าตรงกับความต้องการหรือไม่
Post Reply
ajsudkedt
Gold
Gold
Posts: 1182
Joined: Thu Jan 28, 2010 11:08 am
Excel Ver: 2021

ขอสูตรจัดรายชื่อตามรูปแบบที่กำหนดครับ

#1

Post by ajsudkedt »

จากข้อมูลในชีต input1
นำมาจับคู่กับข้อมูลในชีต input2
แล้วให้ได้ผลลัพธ์ในชีต output
ต้องเขียนสูตรอย่างไร
ตามภาพ
ขอบคุณครับ
You do not have the required permissions to view the files attached to this post.
Last edited by ajsudkedt on Fri Apr 14, 2023 9:46 am, edited 1 time in total.
Top
ajsudkedt
Gold
Gold
Posts: 1182
Joined: Thu Jan 28, 2010 11:08 am
Excel Ver: 2021

Re: ขอสูตรจัดรายชื่อตามรูปแบบที่กำหนดครับ

#2

Post by ajsudkedt »

จากข้อมูลในชีต input1
นำมาจับคู่กับข้อมูลในชีต input2
แล้วให้ได้ผลลัพธ์ในชีต output
ต้องเขียนสูตรอย่างไร
ตามไฟล์แนบ
ขอบคุณครับ
You do not have the required permissions to view the files attached to this post.
Top
User avatar
norkaz
Gold
Gold
Posts: 1805
Joined: Wed Jan 12, 2011 7:59 pm
Excel Ver: 2013,365

Re: ขอสูตรจัดรายชื่อตามรูปแบบที่กำหนดครับ

#3

Post by norkaz »

...

ในการใช้งานจริง ควรปรับฐานข้อมูลให้อยู่ในรูปตารางที่ง่ายในการนำไปใช้ เช่น

ชีท input2 ควรแยก รหัส คำ นำหน้าชื่อ ชื่อ นามสกุล ออกมาจากกัน อาจจะใช้ วิธีการ

ง่ายๆ เช่น Text to columns ไปช่วยเป็นต้น หรือใช้สูตร เช่น ชีท input2

C2
=LEFT(B2,3)

D2
=LOOKUP(99,SEARCH({"นาย","นาง","นางสาว"},B2),{"นาย","นาง","นางสาว"})

E2
=LEFT(MID(B2,8+LEN(D2),99),SEARCH(" ",MID(B2,8+LEN(D2),99))-1)

F2
=TRIM(SUBSTITUTE(MID(B2,8+LEN(D2),99),E2,""))

========

ที่ชีท output

F2
=COUNT(INDEX(--(SEARCH(MID(input1!C2:F2,4,3),input2!$B$2:$B$150)>0),0))
Copy ลงไป

A2
=INDEX(input1!A:A,AGGREGATE(15,6,ROW($F$2:$F$13)/(COLUMN($A2:$Z2)<=$F$2:$F$13),ROWS(G$2:G2)))

B2:Dxx
=IFERROR(VLOOKUP(LOOKUP(999,SEARCH(input2!$C$2:$C$150,VLOOKUP($A2,input1!$A$2:$F$4,2+COUNTIF($A$2:$A2,$A2),0)),input2!$C$2:$C$150),input2!$C$2:$F$150,COLUMNS($A2:B2),0),"")


** เพื่อนสมาชิกกรุณา คลิกโฆษณาหน้าเพจ เพื่อเป็นการช่วยกันสนับสนุนฟอรั่มครับ

Norkaz
You do not have the required permissions to view the files attached to this post.
Top
User avatar
norkaz
Gold
Gold
Posts: 1805
Joined: Wed Jan 12, 2011 7:59 pm
Excel Ver: 2013,365

Re: ขอสูตรจัดรายชื่อตามรูปแบบที่กำหนดครับ

#4

Post by norkaz »

...

ถ้าไม่จัดฐานข้อมูล ใช้จากโจทย์เดิม

ตัวอย่างสูตร ชีท output

F2 (Helper)

=COUNT(INDEX(SEARCH(MID(input1!C2:F2,4,3),input2!$B$2:$B$150),0))

A2

=INDEX(input1!A:A,AGGREGATE(15,6,ROW($F$2:$F$16)/(COLUMN($A$2:$L$2)<=$F$2:$F$16),ROWS($A$2:A2)))

B2

=IFERROR(LOOKUP(99,SEARCH({"นาย","นาง","นางสาว"},INDEX(input2!$B$2:$B$150,INDEX(MATCH(INDEX(MID(INDEX(input1!$C$2:$F$4,MATCH($A2,input1!$A$2:$A$4,0),0),4,3),0),INDEX(LEFT(input2!$B$2:$B$150,3),0),0),COUNTIF($A$2:$A2,$A2)))),{"นาย","นาง","นางสาว"}),"")

C2

=IFERROR(LEFT(MID(INDEX(input2!$B$2:$B$150,INDEX(MATCH(INDEX(MID(INDEX(input1!$C$2:$F$4,MATCH($A2,input1!$A$2:$A$4,0),0),4,3),0),INDEX(LEFT(input2!$B$2:$B$150,3),0),0),COUNTIF($A$2:$A2,$A2))),LEN($B2)+8,99),SEARCH(" ",MID(INDEX(input2!$B$2:$B$150,INDEX(MATCH(INDEX(MID(INDEX(input1!$C$2:$F$4,MATCH($A2,input1!$A$2:$A$4,0),0),4,3),0),INDEX(LEFT(input2!$B$2:$B$150,3),0),0),COUNTIF($A$2:$A2,$A2))),LEN($B2)+8,99))-1),"")

D2

=IFERROR(TRIM(SUBSTITUTE(MID(INDEX(input2!$B$2:$B$150,INDEX(MATCH(INDEX(MID(INDEX(input1!$C$2:$F$4,MATCH($A2,input1!$A$2:$A$4,0),0),4,3),0),INDEX(LEFT(input2!$B$2:$B$150,3),0),0),COUNTIF($A$2:$A2,$A2))),LEN($B2)+8,99),C2,"")),"")

** เพื่อนสมาชิกกรุณา คลิกโฆษณาหน้าเพจ เพื่อเป็นการช่วยกันสนับสนุนฟอรั่มครับ

Norkaz
You do not have the required permissions to view the files attached to this post.
Top
ajsudkedt
Gold
Gold
Posts: 1182
Joined: Thu Jan 28, 2010 11:08 am
Excel Ver: 2021

Re: ขอสูตรจัดรายชื่อตามรูปแบบที่กำหนดครับ

#5

Post by ajsudkedt »

ต้องขออภัยด้วยครับ
ในชีท input2
ในคอลัมน์ B
จำนวนเคาะวรรค
ระหว่างเลข กับ คำนำหน้าชื่อ
จะต้องห่างกันแค่ 2 เคาะวรรค
จะต้องปรับสูตรอย่างไรครับ
ตามภาพแล้วไฟล์แนบครับ
ขอบคุณครับ
You do not have the required permissions to view the files attached to this post.
Top
User avatar
norkaz
Gold
Gold
Posts: 1805
Joined: Wed Jan 12, 2011 7:59 pm
Excel Ver: 2013,365

Re: ขอสูตรจัดรายชื่อตามรูปแบบที่กำหนดครับ

#6

Post by norkaz »

...

ปรับที่ +8 ให้เป็น +6

F2 - Helper

=COUNT(INDEX(SEARCH(MID(input1!C2:F2,4,3),input2!$B$2:$B$150),0))

A2

=INDEX(input1!A:A,AGGREGATE(15,6,ROW($F$2:$F$16)/(COLUMN($A$2:$L$2)<=$F$2:$F$16),ROWS($A$2:A2)))

B2

=IFERROR(LOOKUP(99,SEARCH({"นาย","นาง","นางสาว"},INDEX(input2!$B$2:$B$150,INDEX(MATCH(INDEX(MID(INDEX(input1!$C$2:$F$4,MATCH($A2,input1!$A$2:$A$4,0),0),4,3),0),INDEX(LEFT(input2!$B$2:$B$150,3),0),0),COUNTIF($A$2:$A2,$A2)))),{"นาย","นาง","นางสาว"}),"")

C2

=IFERROR(LEFT(MID(INDEX(input2!$B$2:$B$150,INDEX(MATCH(INDEX(MID(INDEX(input1!$C$2:$F$4,MATCH($A2,input1!$A$2:$A$4,0),0),4,3),0),INDEX(LEFT(input2!$B$2:$B$150,3),0),0),COUNTIF($A$2:$A2,$A2))),LEN($B2)+6,99),SEARCH(" ",MID(INDEX(input2!$B$2:$B$150,INDEX(MATCH(INDEX(MID(INDEX(input1!$C$2:$F$4,MATCH($A2,input1!$A$2:$A$4,0),0),4,3),0),INDEX(LEFT(input2!$B$2:$B$150,3),0),0),COUNTIF($A$2:$A2,$A2))),LEN($B2)+6,99))-1),"")

D2
=IFERROR(TRIM(SUBSTITUTE(MID(INDEX(input2!$B$2:$B$150,INDEX(MATCH(INDEX(MID(INDEX(input1!$C$2:$F$4,MATCH($A2,input1!$A$2:$A$4,0),0),4,3),0),INDEX(LEFT(input2!$B$2:$B$150,3),0),0),COUNTIF($A$2:$A2,$A2))),LEN($B2)+6,99),C2,"")),"")

** เพื่อนสมาชิกกรุณา คลิกโฆษณาหน้าเพจ เพื่อเป็นการช่วยกันสนับสนุนฟอรั่มครับ

Norkaz
You do not have the required permissions to view the files attached to this post.
Top
User avatar
norkaz
Gold
Gold
Posts: 1805
Joined: Wed Jan 12, 2011 7:59 pm
Excel Ver: 2013,365

Re: ขอสูตรจัดรายชื่อตามรูปแบบที่กำหนดครับ

#7

Post by norkaz »

...

อีกวิธี ไม่ต้องใช้ Helper ปรับสูตรที่ A2 ส่วน B2, C2, D2 ใช้สูตรเดิม


A2

=IFERROR(INDEX(input1!A:A,AGGREGATE(15,6,ROW(input1!$C$2:$C$99)/(--MID(input1!$C$2:$F$99,4,1)>=0),ROWS($A$2:A2))),"")

B2

=IFERROR(LOOKUP(99,SEARCH({"นาย","นาง","นางสาว"},INDEX(input2!$B$2:$B$150,INDEX(MATCH(INDEX(MID(INDEX(input1!$C$2:$F$4,MATCH($A2,input1!$A$2:$A$4,0),0),4,3),0),INDEX(LEFT(input2!$B$2:$B$150,3),0),0),COUNTIF($A$2:$A2,$A2)))),{"นาย","นาง","นางสาว"}),"")

C2

=IFERROR(LEFT(MID(INDEX(input2!$B$2:$B$150,INDEX(MATCH(INDEX(MID(INDEX(input1!$C$2:$F$4,MATCH($A2,input1!$A$2:$A$4,0),0),4,3),0),INDEX(LEFT(input2!$B$2:$B$150,3),0),0),COUNTIF($A$2:$A2,$A2))),LEN($B2)+6,99),SEARCH(" ",MID(INDEX(input2!$B$2:$B$150,INDEX(MATCH(INDEX(MID(INDEX(input1!$C$2:$F$4,MATCH($A2,input1!$A$2:$A$4,0),0),4,3),0),INDEX(LEFT(input2!$B$2:$B$150,3),0),0),COUNTIF($A$2:$A2,$A2))),LEN($B2)+6,99))-1),"")

D2

=IFERROR(TRIM(SUBSTITUTE(MID(INDEX(input2!$B$2:$B$150,INDEX(MATCH(INDEX(MID(INDEX(input1!$C$2:$F$4,MATCH($A2,input1!$A$2:$A$4,0),0),4,3),0),INDEX(LEFT(input2!$B$2:$B$150,3),0),0),COUNTIF($A$2:$A2,$A2))),LEN($B2)+6,99),C2,"")),"")


** เพื่อนสมาชิกกรุณา คลิกโฆษณาหน้าเพจ เพื่อเป็นการช่วยกันสนับสนุนฟอรั่มครับ

Norkaz
You do not have the required permissions to view the files attached to this post.
Top
ajsudkedt
Gold
Gold
Posts: 1182
Joined: Thu Jan 28, 2010 11:08 am
Excel Ver: 2021

Re: ขอสูตรจัดรายชื่อตามรูปแบบที่กำหนดครับ

#8

Post by ajsudkedt »

หากมีการเพิ่มข้อมูลในชีท input1
ต้องปรับสูตรอย่างไร
ตามภาพและไฟล์แนบครับ
ขอบคุณครับ
You do not have the required permissions to view the files attached to this post.
Top
User avatar
norkaz
Gold
Gold
Posts: 1805
Joined: Wed Jan 12, 2011 7:59 pm
Excel Ver: 2013,365

Re: ขอสูตรจัดรายชื่อตามรูปแบบที่กำหนดครับ

#9

Post by norkaz »

...


A2
=IFERROR(INDEX(input1!A:A,AGGREGATE(15,6,ROW(input1!$C$2:$C$999)/(--MID(input1!$C$2:$F$999,4,1)>=0),ROWS($A$2:A2))),"")

B2
=IFERROR(LOOKUP(999,SEARCH({"นาย","นาง","นางสาว"},LOOKUP(999,SEARCH(MID(VLOOKUP(A2,input1!$A$2:$F$999,2+COUNTIF($A$2:A2,A2),0),4,3),LEFT(input2!$B$2:$B$999,3)),input2!$B$2:$B$999)),{"นาย","นาง","นางสาว"}),"")

C2
=IFERROR(MID(VLOOKUP(A2,input1!$A$2:$F$999,COUNTIF($A$2:A2,A2)+2,0),9,999),"")

D2
=IFERROR(TRIM(SUBSTITUTE(SUBSTITUTE(MID(LOOKUP(999,SEARCH(MID(VLOOKUP(A2,input1!$A$2:$F$999,COUNTIF($A$2:A2,A2)+2,0),4,3),input2!$B$2:$B$999),input2!$B$2:$B$999),6,999),B2,""),C2,"")),"")


** เพื่อนสมาชิกกรุณา คลิกโฆษณาหน้าเพจ เพื่อเป็นการช่วยกันสนับสนุนฟอรั่มครับ

Norkaz
You do not have the required permissions to view the files attached to this post.
Top
ajsudkedt
Gold
Gold
Posts: 1182
Joined: Thu Jan 28, 2010 11:08 am
Excel Ver: 2021

Re: ขอสูตรจัดรายชื่อตามรูปแบบที่กำหนดครับ

#10

Post by ajsudkedt »

norkaz wrote: Fri Apr 14, 2023 7:17 pm ...


A2
=IFERROR(INDEX(input1!A:A,AGGREGATE(15,6,ROW(input1!$C$2:$C$999)/(--MID(input1!$C$2:$F$999,4,1)>=0),ROWS($A$2:A2))),"")

B2
=IFERROR(LOOKUP(999,SEARCH({"นาย","นาง","นางสาว"},LOOKUP(999,SEARCH(MID(VLOOKUP(A2,input1!$A$2:$F$999,2+COUNTIF($A$2:A2,A2),0),4,3),LEFT(input2!$B$2:$B$999,3)),input2!$B$2:$B$999)),{"นาย","นาง","นางสาว"}),"")

C2
=IFERROR(MID(VLOOKUP(A2,input1!$A$2:$F$999,COUNTIF($A$2:A2,A2)+2,0),9,999),"")

D2
=IFERROR(TRIM(SUBSTITUTE(SUBSTITUTE(MID(LOOKUP(999,SEARCH(MID(VLOOKUP(A2,input1!$A$2:$F$999,COUNTIF($A$2:A2,A2)+2,0),4,3),input2!$B$2:$B$999),input2!$B$2:$B$999),6,999),B2,""),C2,"")),"")


** เพื่อนสมาชิกกรุณา คลิกโฆษณาหน้าเพจ เพื่อเป็นการช่วยกันสนับสนุนฟอรั่มครับ

Norkaz
กราบขอบพระคุณท่านมาก ๆ ครับ
สูตรที่ท่านให้มา ได้ผลดั่งต้องการเลยครับ
Top
Post Reply

Return to “Excel”