รบกวนจัดกลุ่มข้อความด้วยค่ะ

[kitwong]

สมมุติ
A B
25

25

25

25

25 2
หนูอยากให้แสดงเป็นกลุ่ม 5x25 ทุกครั้งที่เจอตัวเลขช่อง B ให้จัดกลุ่มนั้นค่ะ ตามไฟลล์แนบคะ หนูลองเขียนสูตรมาบ้างส่วนแล้ว อยากให้รบกวนแก้ไขด้วยคะ

[snasui]

ตัวอย่างสูตรครับ

เซลล์ E4 คีย์

=IF(N(D4),COUNT(C4:INDEX(C$4:C4,LOOKUP(2,1/(D$2:D3<>""),ROW($D$2:$D3)-ROW($D$2)+1)))&"x"&C4,"")

Enter > Copy ลงด้านล่าง

[kitwong]

ขอบคุณค่ะ แต่หนูขอเพิ่มเงื่อนไขได้มั้ยคะ ถ้าตัวจัดกลุ่มไม่เหมือนกัน สมุมติ
A B
25
25
23
23 2 คำตอบที่หนูอยากได้ 2X23+2X25 รบกวนด้วยคะ

[DhitiBank]

2016-10-14 10_54_18-Microsoft Excel - การจัดกลุ่ม.xlsx [Read-Only].png

ลองแบบนี้ครับ ใช้คอลัมน์ช่วย

F4
=IF(C4="","",IF(C4<>C6,IF(COUNTIF(C4:INDEX(C$2:C2,LOOKUP(2,1/((C$2:C2<>C4)*(C$2:C2<>"")),ROW(C$2:C2)-ROW(C$2)+1)),C4)=1,"+","+"&COUNTIF(C4:INDEX(C$2:C2,LOOKUP(2,1/((C$2:C2<>C4)*(C$2:C2<>"")),ROW(C$2:C2)-ROW(C$2)+1)),C4)&"x")&C4,""))
Enter >> คัดลอกลงล่าง

G4
=IFERROR(IF(N($D4),INDEX($F$4:$F4,SMALL(IF($F$4:$F4<>"",IF(ROW($F$4:$F4)>LOOKUP(2,1/($D$2:$D2<>""),ROW($D$2:$D2)),ROW($F$4:$F4)-ROW($F$4)+1)),COLUMNS($G4:G4))),""),"")
กด Ctrl+Shift ค้างไว้แล้ว Enter >> คัดลอกไปทางขวาเผื่อสัก 4-5 คอลัมน์ แล้วคัดลอกลงล่าง

E4
=IF(N(D4),MID(G4&H4&I4&J4,2,100),"")
Enter >> คัดลอกลงล่าง

หากข้อมูลมีเยอะมากๆ แนะนำว่าค่อยๆ คัดลอกทีละหน่อยครับ เช่นสมมติข้อมูลมี 300 แถว คัดลอกสูตรลงมาสัก 50-100 แถว แล้วลบตำแหน่งที่สูตรแสดงค่าว่างๆ เช่นตำแหน่งที่ 2 และ 3 ในรูปทิ้ง เหลือแค่สูตรต้นแบบในแถวที่ 4 ไว้ก็พอ เพราะสูตรแบบในเซลล์ G4 หากมีมากๆ จะทำให้คำนวณช้าครับ

[kitwong]

ขอบคุณมากๆคะ