Page 1 of 1
คำนวนสูตรหลายเงื่อนไขที่ต้องการ
Posted: Thu May 22, 2014 5:31 pm
by nilatxay
อยากรู้ว่ามีการคำนวนสูตรหลายเงื่อนไขที่ต้องการ
ผมมีข้อมูลอยู่ 2sheet
sheet Traking เป็นsheetที่ต้องได้เอาข้อมูลกานเข้าอบรม
Sheet Summary เป็นsheetเพื่อนสรุปว่า มีคนเข้าอบรมเท่าใด อบรมทังหมดเท่าใดชั่วโมง มีผู้ญิงเข้าอบรบเท่าใด และ อบรบเท่าใดหลักสูตร
โดยมีเงื่อนไขในการคำนวนที่ Business Unit, Department และ Group Couse จากsheet Traking
ผมใช้สูรต Summproduct อ้างอีงได้แค่ สองเงือนไข
Re: คำนวนสูตรหลายเงื่อนไขที่ต้องการ
Posted: Thu May 22, 2014 8:29 pm
by snasui
ตัวอย่างสูตรที่ B7:E7 ตามลำดับ
Code: Select all
B7 =COUNTIFS(Tracking!$G$4:$G$15,$A$4,Tracking!$H$4:$H$15,$A7,Tracking!$F$4:$F$15,LOOKUP(CHAR(255),$B$5:B$5))
C7 =SUMIFS(Tracking!$C$4:$C$15,Tracking!$G$4:$G$15,$A$4,Tracking!$H$4:$H$15,$A7,Tracking!$F$4:$F$15,LOOKUP(CHAR(255),$B$5:C$5))
D7 =COUNTIFS(Tracking!$G$4:$G$15,$A$4,Tracking!$H$4:$H$15,$A7,Tracking!$F$4:$F$15,LOOKUP(CHAR(255),$B$5:D$5),Tracking!$E$4:$E$15,D$6)
E7 =COUNTIFS(Trackingฺ!$G$4:$G$15,$A$4,Tracking!$H$4:$H$15,$A7,Tracking!$F$4:$F$15,LOOKUP(CHAR(255),$B$5:E$5))
Copy B7:E7 ลงด้านล่าง > Copy ไปยังเซลล์ที่เกี่ยวข้อง
Re: คำนวนสูตรหลายเงื่อนไขที่ต้องการ
Posted: Fri May 23, 2014 12:09 pm
by nilatxay
สําหรับ ห้อง E7 (table Course) ต้องการนับแต่ Course ที่ไม้ช้ำกันครับ
เพาะในสูรตที่ให้มามันนับ Course ที่ช้ำกัน
สำหลับตาลางอื่นฯ ภืกต้องตามจุดปะสงที่ต้องการแล้ว
Re: คำนวนสูตรหลายเงื่อนไขที่ต้องการ
Posted: Fri May 23, 2014 4:22 pm
by snasui
ลองปรับสูตรเป็นด้านล่างครับ
Code: Select all
=SUM(IF(FREQUENCY(IF(Tracking!$G$4:$G$15=$A$4,IF(Tracking!$H$4:$H$15=$A7,IF(Tracking!$F$4:$F$15=LOOKUP(CHAR(255),$B$5:E$5),MATCH(Tracking!$A$4:$A$15,Tracking!$A$4:$A$15,0)))),ROW(Tracking!$A$4:$A$15)-ROW(Tracking!$A$4)+1),1))
Ctrl+Shift+Enter > Copy ไปด้านล่างและเซลล์ที่เกี่ยวข้อง
Re: คำนวนสูตรหลายเงื่อนไขที่ต้องการ
Posted: Fri May 23, 2014 5:40 pm
by nilatxay
