Snasui Excel Forum

สวัสดีครับ พี่ๆทุกคน
ต้องการคำนวนพนักงานมาสาย ซึ่งไม่ได้คำนวนเป็นนาที ต้องการทราบแค่ว่าพนักงานท่านนี้มาสายหรือไม่ ในคอลัมน์ D
ซึ่งพนักงานแต่ละท่าน กะการเข้างานไม่เหมือนกัน จึงอยากทราบวิธีการคำนวน ไม่รู้ผมอธิบายงงไหม

ตัวอย่างสูตรครับ

เซลล์ D2 คีย์

=IF(B2<=LEFT(C2,5),"ไม่สาย","สาย")

Enter > Copy ลงด้านล่าง

snasui wrote: Fri Mar 11, 2022 9:16 pm ตัวอย่างสูตรครับ

เซลล์ D2 คีย์

=IF(B2<=LEFT(C2,5),"ไม่สาย","สาย")

Enter > Copy ลงด้านล่าง

ขอถามเพิ่มเติมไว้เป็นความรู้ครับ ในสูตร LEFT(C2,5) เลข 5 นี้มาจากไหนครับ

เลข 5 หมายถึง 5 อักขระตามที่วงไว้ในภาพด้านล่างครับ

snasui wrote: Fri Mar 11, 2022 9:34 pm เลข 5 หมายถึง 5 อักขระตามที่วงไว้ในภาพด้านล่างครับ

5Character.png

ถามอีกเรื่องครับ ถ้าเราอยากทราบจำนวนนาทีที่สาย ต้องสูตรไหนครับ
ผมอยากเก็บแบบพี่ ต้องเริ่มศึกษาจากไหนก่อนครับ เวลาดูคลิปตามยูทูป เราก็เหมือนลอกสูตรไม่มีการดัดแปลง

ช่วยทำตัวอย่างคำตอบมาด้วยว่าต้องการให้แสดงในเซลล์ไหน ด้วยค่าเท่าใด จะได้ตอบได้ตรงประเด็นครับ

BangSeed wrote: Fri Mar 11, 2022 9:46 pm ผมอยากเก็บแบบพี่ ต้องเริ่มศึกษาจากไหนก่อนครับ

ช่วยอธิบายเพิ่มเติมว่าต้องการจะเก็บอะไร อย่างไร ถ้าหมายถึงจะศึกษา Excel และใช้งานได้เก่ง ๆ ก็ต้องอ่านให้มาก ฝึกฝนให้มาก ผมอ่านจาก Help และใน Web ของ Microsoft เป็นหลักครับ

snasui wrote: Fri Mar 11, 2022 10:23 pm ช่วยทำตัวอย่างคำตอบมาด้วยว่าต้องการให้แสดงในเซลล์ไหน ด้วยค่าเท่าใด จะได้ตอบได้ตรงประเด็นครับ

ในคอลัมน์ E ต้องการทราบจำนวนนาที่ที่สาย จากการเข้างานในคอลัมน์ B โดยอ้างอิงกะเข้างานในคอลัมน์ C

ควรใส่คำตอบมาด้วยจะได้ทราบว่าต้องการคำตอบเป็นแบบไหน อย่างไรครับ

ตัวอย่างสูตรที่เซลล์ E2 ครับ

=TEXT(MAX(0,B2-LEFT(C2,5)),"h:mm")

Enter > Copy ลงด้านล่าง

snasui wrote: Mon Mar 14, 2022 10:55 pm ควรใส่คำตอบมาด้วยจะได้ทราบว่าต้องการคำตอบเป็นแบบไหน อย่างไรครับ

ตัวอย่างสูตรที่เซลล์ E2 ครับ

=TEXT(MAX(0,B2-LEFT(C2,5)),"h:mm")

Enter > Copy ลงด้านล่าง

ขอโทษด้วยครับที่ไม่ได้ระบุว่าต้องการแบบไหน แต่แบบที่อาจารย์ส่งมา คือที่ผมต้องการแล้วครับ
ขอบพระคุณครับ

ต้องการเอาผลรวมของนาทีที่สาย ใน Sheet ที่ 1 และ Sheet 2 ไปรวมใน Sheet "จำนวนนาทีทั้งเดือน" อธิบายงงไหมครับ

ตัวอย่างสูตรตามด้านล่างครับ

1. ที่คอลัมน์ G เริ่มจาก G2 ของแต่ละชีตปรับสูตรให้แสดงค่าเป็นตัวเลขที่แท้จริงเสียก่อนเป็น
   =TEXT(MAX(0,D7-LEFT(E7,5)),"h:mm")+0
   Enter > Copy ลงด้านล่าง
2. ที่ A2 คีย์
   =IFERROR(TRIM(MID(SUBSTITUTE(INDEX(UNIQUE(FILTERXML("<t><s>"&TEXTJOIN("</s><s>",TRUE,'1'!$A$2:$A$24&"|"&'1'!$B$2:$B$24&"|"&'1'!$C$2:$C$24,'2'!$A$2:$A$24&"|"&'2'!$B$2:$B$24&"|"&'2'!$C$2:$C$24)&"</s></t>","//s")),ROWS(A$2:A2)),"|",REPT(" ",50)),50*(COLUMNS($A2:A2)-1)+1,50)),"")
   Enter > Copy ไปด้านขวาถึง C2 > Copy ลงด้านล่าง
3. ที่ D2 คีย์
   =IF(A2="","",SUM(SUMIFS(INDIRECT("'"&{1,2}&"'!G2:G24"),INDIRECT("'"&{1,2}&"'!A2:A24"),$A2,INDIRECT("'"&{1,2}&"'!B2:B24"),$B2,INDIRECT("'"&{1,2}&"'!C2:C24"),$C2)))
   Enter > Copy ลงด้านล่าง

A2

=LET(a,FILTERXML("<x><m>"&TEXTJOIN("</m><m>",,'1:2'!A2:A99)&"</m></x>","//m"),b,FILTERXML("<x><m>"&TEXTJOIN("</m><m>",,'1:2'!B2:B99)&"</m></x>","//m"),c,FILTERXML("<x><m>"&TEXTJOIN("</m><m>",,'1:2'!C2:C99)&"</m></x>","//m"),n,FILTERXML("<x><m>"&TEXTJOIN("</m><m>",,'1:2'!G2:G99)&"</m></x>","//m"),abc,CHOOSE({1,2,3},a,b,c),u,UNIQUE(abc),CHOOSE(SEQUENCE(,4),u,u,u,MMULT(--(TRANSPOSE(a&b&c)=(UNIQUE(a&b&c))),n)))