ขอความช่วยปรับโค๊ด VBA แยก","ใน cell

[prajak]

ต้องการแยกสัญลักษณ์ ","ที่อยู่ในคอลัมน์ F หลังจากแยกแล้ว นำไปวางคอลัมน์ G,H,I,J ขึ้นอยู่กับจำนวน","
ผมพยายามเขียนโดยใช้ Array แต่ก็ยังติดอยู่
รบกวนอาจารย์ช่วยปรับ Code ให้ หากมีเทคนิคอะไร ช่วยแนะนำด้วยครับ

[prajak]

Code: Select all

Sub lotlist()
Dim Lot As Range
Set Lot = ActiveSheet.Range(Cells(2, 7), Cells(Rows.Count, 7).End(xlUp))
Dim ArrLot() As String
Dim i As interger
ArrLot(i) = Split(Lot(i), ",")
Lotmax = UBound(ArrLot(i))
    For i = 1 To ActiveSheet.Range(Cells(2, 7), Cells(Rows.Count, 7).End(xlUp))
        Dim J As Integer
        For J = 0 To UBound(ArrLot(i))
        Lot.Offset(i, 1).Value = ArrLot(i)
        Next
    Next
    
End Sub

[snasui]

ตัวอย่าง Code ครับ

Code: Select all

Dim Lot As Range
Dim rng As Range
Dim arrLot As Variant
With ActiveSheet
    Set Lot = .Range(.Cells(2, 6), .Cells(.Rows.Count, 6).End(xlUp))
End With
For Each rng In Lot
    arrLot = Split(rng.Value, ",")
    rng.Offset(0, 1).Resize(1, UBound(arrLot) + 1).Value = arrLot
Next rng

[Bo_ry]

อันนี้แบบใช้สูตร G2 =TRIM(MID(SUBSTITUTE($F2,",",REPT(" ",LEN($F2))),(COLUMNS($G2:G2)-1)*LEN($F2)+1,LEN($F2)))

[prajak]

ขอบคุณมากครับ
สามารถทำได้แล้วครับ กำลังศึกษาลักษณะของ สูตรและโค๊ดอยู่ครับ