Page 1 of 1
ดึงข้อมูลหลายรายการ
Posted: Wed Dec 26, 2018 4:20 pm
by March201711
สอบถามหน่อยค่ะ ถ้าจะดึงข้อมูลจาก sheet data มาที่ sheet sum โดยมีเงื่อนไขว่าต้องดึงข้อมูลตามวันที่ PD และ สกุลเงิน ต้องใช้สูตรไรคะ
เช่น sheet Mr.Q มี Product CCC วันที่ 11/12/18 ขาBU สุกลเงิน USD ต้องดึงอย่างไรคะถึงได้ข้อมูลตามข้างต้น
ขอบคุณค่ะ
Re: ดึงข้อมูลหลายรายการ
Posted: Wed Dec 26, 2018 5:01 pm
by puriwutpokin
ที่ B5=IFERROR(INDEX(data!$H$3:$H$50,MATCH(1,INDEX((data!$E$3:$E$50=$A5)*(data!$C$3:$C$50=RIGHT(LOOKUP(CHAR(255),$B$3:B$3),3))*(data!$I$3:$I$50=B$4),),)),"") คัดลอกไปทางขวาและลงล่างครับ
Re: ดึงข้อมูลหลายรายการ
Posted: Wed Dec 26, 2018 6:56 pm
by Bo_ry
อีกแบบ
B5
=SUMPRODUCT(ISNUMBER(SEARCH(data!$C$1:$C$50,LOOKUP("Z",$B$3:B$3)))*(data!$I$1:$I$50=B$4)*(data!$E$1:$E$50=$A5),data!$H$1:$H$50)
Re: ดึงข้อมูลหลายรายการ
Posted: Wed Dec 26, 2018 8:54 pm
by March201711
ไม่ได้บาง column ค่ะ ติดตรงเครื่องหมาย - และ + ค่ะ
ต้องดูว่าเป็น ขา Buy หรือ Sell โดยดูจากsheet data column G ค่ะ
ถ้าเป็น Buy ต้องเป็นยอดติดลบ
ถ้าเป็น Sell ต้องเป็นยอดบวก
Re: ดึงข้อมูลหลายรายการ
Posted: Wed Dec 26, 2018 9:58 pm
by Bo_ry
B5
=SUMPRODUCT(ISNUMBER(SEARCH(data!$C$1:$C$50,LOOKUP("Z",$B$3:B$3)))*(data!$I$1:$I$50=B$4)*(data!$E$1:$E$50=$A5),data!$H$1:$H$50,(data!$G$1:$G$50="SE")-(data!$G$1:$G$50="BU"))
Re: ดึงข้อมูลหลายรายการ
Posted: Wed Dec 26, 2018 10:22 pm
by March201711
ได้แล้วค่ะ แต่ช่วยอธิบายสูตรให้เข้าใจหน่อยค่ะ สงสัยค่ะ ทำไมต้อง lookup"Z" ด้วยคะ ในdata ไม่มีค่า z เลย และถ้ามีเงื่อนไขเพิ่มสามารถ lookup data ต่อๆไปได้เลยใช่ไหมคะ ขอบคุณค่ะ
Re: ดึงข้อมูลหลายรายการ
Posted: Thu Dec 27, 2018 10:24 am
by Bo_ry
LOOKUP(lookup_value, lookup_vector, [result_vector])
เป็น approximate match จะหาค่าที่น้อยกว่าหรือเท่า lookup value เสมอ
lookup("z", range)
ถ้า range มีค่าที่น้อยกว่าตัว lookup valueก็จะได้ค่านั้น
เทียบค่าโดยใช้ =code( )
Code("A") =65 Char(65) ="A"
Code("Z") =90
Code("a") =97
Code("z") =122
Row 3 ขึ้นต้นด้วย "Axxx" "Z" มากว่า "A" ก็จะใช้ได้
ถ้า Row 3 ขึ้นต้นด้วย "axxx" "Z" น้อยกว่า "a" จะหาค่าไม่ได้ ต้องใช้ "z" เล็กแทน หรือใช้ค่ามากสุดคือ char(255)
ที่ต้องใช้เพราะ B3:D3 merge กันทำให้ C3 D3 เป็นค่าว่าง
Re: ดึงข้อมูลหลายรายการ
Posted: Fri Dec 28, 2018 9:22 pm
by March201711
แต่สงสัยนิดนึงค่ะ ถ้าเขียนเงื่อนไขว่าถ้าเป็นค่าว่าง ให้แสดงค่าว่าง ถ้าไม่ใช่ให้แสดงค่านั้น
เช่น ถ้า sheet data column e40 เป้นค่าว่าง อยากให้ sheet sum เป็นค่าว่างเหมือนกัน แต่ที่สูตรแสดงมาเป็น ค่า00/01/1900 เพราะอะไรคะ
Re: ดึงข้อมูลหลายรายการ
Posted: Fri Dec 28, 2018 9:39 pm
by puriwutpokin
ปรับสูตรที่ A5=IFERROR(INDEX(data!$E$3:$E$50,SMALL(IF(ISNUMBER(data!$E$3:$E$50),ROW(data!$E$3:$E$50)-ROW(data!$E$2)),ROWS(A$5:A5))),"") กด Ctrl+Shift+Enter คัดลอกลงครับ
Re: ดึงข้อมูลหลายรายการ
Posted: Fri Dec 28, 2018 10:23 pm
by March201711
ถ้าไม่ใช้ array สามารถทำแบบอื่นได้ไหมคะ
Re: ดึงข้อมูลหลายรายการ
Posted: Fri Dec 28, 2018 10:41 pm
by puriwutpokin
March201711 wrote: Fri Dec 28, 2018 10:23 pm
ถ้าไม่ใช้ array สามารถทำแบบอื่นได้ไหมคะ
ถ้าใช้ office 2010 ขึ้นไปก็ใช้เป็น
=IFERROR(INDEX(data!$E$3:$E$50,AGGREGATE(15,6,(ROW(data!$E$3:$E$50)-ROW(data!$E$2))/ISNUMBER(data!$E$3:$E$50),ROWS(A$5:A5))),"")