Snasui Excel Forum

สวัสดีค่ะ

เงื่อนไขคือ ถ้าต้องการ อ้างอิงตำแหน่งของ คอลัม A Sheet1 ว่า A นั้นอยู่ในตำแหน่งใดของ sheet2 เพื่อที่จะนำตำแหน่งนั้น กลับมา OFFSET ค่า กลับมา Sheet1 ค่ะ
ทางผู้เขียนได้ลองเขียนสูตรขึ้นมาแล้ว แต่สูตรมีความยาวมาก เมื่อใช้งานจริง ข้อมูลมีหลายร้อยบรรทัด ทำให้ โปรแกรมช้า
รบกวนผู้รู้ ช่วย แนะนำ การเขียนสตรูให้สั้น กว่านี้ทีค่ะ ขอบคุณค่ะ
สูตรที่เขียน
=OFFSET(Sheet2!$A$1,(IF(ISNA(MATCH(A3,Sheet2!F:F,0)),0,MATCH(A3,Sheet2!F:F,0))+IF(ISNA(MATCH(A3,Sheet2!G:G,0)),0,MATCH(A3,Sheet2!G:G,0))+IF(ISNA(MATCH(A3,Sheet2!H:H,0)),0,MATCH(A3,Sheet2!H:H,0)))-1,0,1,1)
[/img]

กรุณาแนบไฟล์ Excel มาด้วยจะได้สะดวกต่อเพื่อนสมาชิกในตรวจ สอบแก้ไข ปรับปรุงสูตรครับ

แนบไฟล์มาให้มาแล้วค่ะ รบกวน อาจารย์ ด้วย นะคะ

ใช้ column ช่วยแทนครับ

ตามแนบได้คำตอบตรงไหม

อ่านโจทย์ไม่ค่อยเข้าใจ
ขออ้างอิงคำตอบ จากท่าน Supachok

สูตรตัวอย่างอีกแบบ

ที่ Sheet1

G3

=AGGREGATE(15,6,{1,2,3}/(A3=Sheet2!$F$3:$H$13),1)

Copy ลงล่าง

Norkaz

ขอบคุณพี่ๆ มากค่ะ ทำได้แล้ว

norkaz wrote: Wed Mar 24, 2021 12:13 am อ่านโจทย์ไม่ค่อยเข้าใจ
ขออ้างอิงคำตอบ จากท่าน Supachok

สูตรตัวอย่างอีกแบบ

ที่ Sheet1

G3

=AGGREGATE(15,6,{1,2,3}/(A3=Sheet2!$F$3:$H$13),1)

Copy ลงล่าง

Norkaz

แบบ ไม่มี column ช่วยครับ
K.norkaz
{1,2,3} ช่วยให้ผมเข้าใจมากขึ้นว่าเป็นการจับคู่แบบ column

=INDEX(Sheet2!$A$3:$E$13,MATCH($A23,INDEX(Sheet2!$F$3:$H$13,0,AGGREGATE(15,6,{1,2,3}/($A23=Sheet2!$F$3:$H$13),1)),0),COLUMN()-1)

B3
=INDEX(Sheet2!$A$3:$A$13,MAX(INDEX(ROW(Sheet2!$F$3:$H$13)*(Sheet2!$F$3:$H$13=$A3),))-ROW(Sheet2!$A$2))

แถมอีกตัวอย่าง

B3

=INDEX(Sheet2!$A$1:$E$13,AGGREGATE(15,6,ROW($F$3:$F$13)/($A3=Sheet2!$F$3:$H$13),1),COLUMN(A1))

Copy ไปขวา และลงล่าง

Norkaz

โจทย์เรียงคอลัมน์ อยู่แล้ว (ไม่ได้สลับ)
อาจจะไม่จำเป็น ต้องใช้ INDEX(Range,Row,Column)

สามารถ INDEX ไปทีละคอลัมน์ เรียง A-B-C-D-E ไปได้

อีกแบบ

B3

=INDEX(Sheet2!A$1:A$13,AGGREGATE(15,6,ROW($F$3:$F$13)/($A3=Sheet2!$F$3:$H$13),1))

** อาจารย์ Bo_ry
สูตรสวยครับ ใช้ INDEX ไปครอบบังคับไม่ให้ติด Array เต็มรูป

Norkaz