Page 1 of 1
โชว์ข้อมูล 12 รายการ ถึงวัน commitment
Posted: Wed Sep 24, 2025 4:14 pm
by Xcelvba
ต้องการใช้สูตร กรองข้อมูล มาแค่ 12 รายการ (ถ้าเกินตัดออก) จากชีท Task List เงื่อนไข คือ Action Date (E) ถึง Commitments Date (H)
ให้โชว์ในชีท Calendar B5 , C5 , ....... ไปจนคบวันที่กำหนด
เช่น
ชีท
B5:B16 (วันที่ 1 )
B5 โชว์ ทดสอบ
B6 โชว์ f
C5:C16 (วันที่ 2)
ต้องโชว์ ทดสอบ (เนื่องจากมากจาก commitments ของ รายการ ทดสอบ ยังไม่สิ้นสุด ไปถึงวันที่ 5)
ขอบคุณครับ
Re: โชว์ข้อมูล 12 รายการ ถึงวัน commitment
Posted: Wed Sep 24, 2025 7:30 pm
by snasui
ตัวอย่างสูตรที่ B5 ครับ
=IFERROR(INDEX('Task List'!$B:$B,AGGREGATE(15,6,ROW(Table4[Task])/(Table4[Action Date]=B$4),ROWS(B$5:B5))),"")
Enter > Copy ไปด้านขวาและลงด้านล่าง
Copy สูตรที่ B5 ไปวางใน B18 โดยเปลี่ยนเป็น
=IFERROR(INDEX('Task List'!$B:$B,AGGREGATE(15,6,ROW(Table4[Task])/(Table4[Action Date]=B$17),ROWS(B$18:B18))),"")
Copy ไปด้านขวาและลงด้านล่าง
Copy ไปยังวันที่เหลือและเปลี่ยนสูตรให้สอดคล้องกับพื้นที่นั้น ๆ โดยเปลี่ยนตำแหน่งตามตัวอย่างในสูตรด้านบน
ครับ
Re: โชว์ข้อมูล 12 รายการ ถึงวัน commitment
Posted: Thu Sep 25, 2025 8:32 am
by Xcelvba
ยังไม่ได้ครับ อาจารย์ คำตอบที่ถูกต้อง ต้องเป็ฯตามรูปแนบครับ เพราะ วันที่ Commitment ถึงวันที่ 5/9/2025 ครับ
Re: โชว์ข้อมูล 12 รายการ ถึงวัน commitment
Posted: Thu Sep 25, 2025 8:50 am
by snasui
ตัวอย่างการปรับสูตรครับ
ที่ B5 คีย์
=IFERROR(INDEX('Task List'!$B:$B,AGGREGATE(15,6,ROW(Table4[Task])/((Table4[Action Date]<=B$4)*(Table4[Commitments Date]>=B$4)),ROWS(B$5:B5))),"")
Enter > Copy ไปทางขวาและลงด้านล่างแล้วปรับใช้กับวันที่อื่น ๆ ในบรรทัดล่างที่เหลือ
สูตรนี้พิจารณา 2 เงื่อนไขตามที่ระบายสี
หากไม่เข้าทั้งสองเงื่อนไขจะไม่ได้คำตอบ ดังนั้น B5 แสดงคำว่า "ทดสอบ" ส่วน B6 แสดงค่าว่างไม่ใช่ f ทั้งนี้เพราะ H13 ไม่มีวันที่
หากมีเงื่อนไขใดเพิ่มเติมกรุณาเขียนมาให้ครบถ้วน ยกเว้นสะดวกในการปรับสูตรเองครับ
สำหรับสูตรนี้เป็นการพิจาณาพร้อมกัน หากเข้าเงื่อนใดเงื่อนไขหนึ่งถือว่าเข้าเงื่อนไข เซลล์ B5 คีย์
=LOOKUP(CHAR(255),CHOOSE({1,2,3},"",INDEX('Task List'!$B:$B,AGGREGATE(15,6,ROW(Table4[Task])/((Table4[Action Date]<=B$4)*(Table4[Commitments Date]>=B$4)),ROWS(B$5:B5))),INDEX('Task List'!$B:$B,AGGREGATE(15,6,ROW(Table4[Task])/(Table4[Action Date]=B$4),ROWS(B$5:B5)))))
Enter > Copy ไปทางขวาและลงด้านล่าง ปรับสูตรใช้กับบรรทัดวันที่ด้านล่างที่เหลือ
Re: โชว์ข้อมูล 12 รายการ ถึงวัน commitment
Posted: Thu Sep 25, 2025 9:08 am
by Xcelvba
ขอบคุณครับอาจารย์ ผมลองเอาไปศึกษาก่อนครับ ปกติ เข้าใจในสูตรนี้
=IFERROR(INDEX('Task List'!$B:$B,AGGREGATE(15,6,ROW(Table4[Task])/((Table4[Action Date]<=B$4)*(Table4[Commitments Date]>=B$4)),ROWS(B$5:B5))),"")
แต่การใช้
=LOOKUP(CHAR(255),CHOOSE({1,2,3},"",INDEX('Task List'!$B:$B,AGGREGATE(15,6,ROW(Table4[Task])/((Table4[Action Date]<=B$4)*(Table4[Commitments Date]>=B$4)),ROWS(B$5:B5))),INDEX('Task List'!$B:$B,AGGREGATE(15,6,ROW(Table4[Task])/(Table4[Action Date]=B$4),ROWS(B$5:B5)))))
ขอทำความเข้าใจก่อนครับ