Snasui Excel Forum

เรียนท่านผู้รู้
ผมต้องการแยกที่อยู่ออกเป็นคอลัมน์ ตามตัวอย่างในไฟล์แนบ แต่เมื่อแยกโดยใช้ Text to column ที่อยู่ที่มีเครื่องหมาย / คั่นอยู่
ผลที่ออกมาในคอลัมน์ B 6 คือ 10-มิ.ย. ซึ่งไม่ใช่คำตอบที่ต้องการ คำตอบทีต้องการคือ 10/6 ไม่ทราบว่าจะใช้สูตรไหนครับ รบกวนท่านผู้ด้วยครับ

ขอบคุณครับ
ประยงค์

รูปแบบตามตัวอย่างที่ส่งมาเลยใช่ไหมครับ

ถ้าใช่ ลองแบบนี้ครับ

1 สมมติที่อยู่แบบเต็มอยู่ในคอลัมน์ A (ตั้งแต่เซลล์ A1)
2 ต้องการแยกแต่ละส่วนมาอยู่ที่คอลัมน์ B, C และ D ตามลำดับ

ที่ B1, C1, D1 คีย์ตามลำดับดังนี้

=LEFT(A1,FIND("ม.",A1,1)-1)

=MID(A1,FIND("ม.",A1,1),FIND("ต.",A1,1)-FIND("ม.",A1,1))

=RIGHT(A1,LEN(A1)-FIND("ต.",A1,1)+1)

รับสูตรโดยการกด Enter จากนั้นคัดลอกลงมาด้านล่างครับ

ลองดูตามไฟล์แนบที่ Sheet2

อีกแนวทางครับ

1. คลุม B2:B3
2. เข้าเมนู Data > Text to columns
3. เลือก Delimited > Next > เลือก Space > Next
4. สังเกตส่วน Preview ด้านล่างคอลัมน์แรกระบายทึบเป็นสีดำ > ให้เลือก Column data format ที่ซ้ายมือบนเป็น Text และหากต้องการให้คอลัมน์ใดในส่วน Preview แสดงเป็น Text ก็ให้เลือก Column นั้นแล้วคลิกเลือก Text จนครบทุกคอลัมน์ > Finish

โอ้ ได้ความรูู้ด้วย ขอบคุณมากครับ ไม่เคยใช้แบบนี้เลย จะได้เอาไปใช้กับข้อมูลที่ export จาก express ที่มีแต่ text file ^o^

ขอบคุณมากครับ คุณ Dhitibank ข้อมูลจริงบางแถว มี คำว่า " ถ."
ถัดจากเลขที่ พอผม Copy สูตรลงมาขึ้น #VALUE!ตามไฟล์ที่แนบ รบกวนอีกรอบครับ

ขอบคุณครับ

หากต้องใช้สูตร จำเป็นจะต้องรู้รูปแบบของข้อมูลที่แน่นอนครับ หากข้อมูลมีการเปลี่ยนแปลงเช่น จากเดิม หมู่ที่ ตามด้วยถนน แต่วันหนึ่งข้อมูลมีการเปลี่ยนโดยเพิ่มซอย หรือชื่อหมู่บ้านคั่นระหว่าง หมู่ที่กับถนน สูตรที่ทำไว้ก็จะใช้ไม่ได้ครับ หรือแสดงผลลัพธ์ผิด ดังนั้น หากจำเป็นต้องใช้สูตรจริงๆ รบกวนขอรูปแบบข้อมูลที่แน่นอนครับคือ บ้านเลขที่ --> ม. --> ซ. --> ฯลฯ

อย่างไรก็ตาม หากไม่ทราบแน่นอน ผมว่าใช้วิธีที่อาจารย์แนะนำ จะสะดวกกว่าครับ และสามารถทำได้กับข้อมูลที่มีจำนวนมากได้อย่างมีประสิทธิภาพครับ

ถ้าหากรูปแบบมีแค่ตามตัวอย่างที่ยกมา ลองแบบนี้ดูก็ได้ครับ

แทรก 2 คอลัมน์ระหว่าง หมู่ที่ กับ ตำบล สมมติว่าที่อยู่แบบเต็มอยู่ที่คอลัมน์ A (ตั้งแต่ A1)

A B C D E F
ที่อยู่ เลขที่ หมู่ที่ ซอย ถนน ตำบล

ลองคีย์ตามนี้ครับ
B2
=IF(ISNUMBER(FIND("ม.",A2)),LEFT(A2,FIND("ม.",A2,1)-1),
IF(ISNUMBER(FIND("ซ.",A2)),LEFT(A2,FIND("ซ.",A2,1)-1),
IF(ISNUMBER(FIND("ถ.",A2)),LEFT(A2,FIND("ถ.",A2,1)-1),
IF(ISNUMBER(FIND("ต.",A2)),LEFT(A2,FIND("ต.",A2,1)-1),""))))

C2
=IF(ISNUMBER(FIND("ม.",$A2)),
MID($A2,FIND("ม.",$A2,1),FIND(" ",$A2,FIND("ม.",$A2)+3)-FIND("ม.",$A2)),
"")

D2
=IF(ISNUMBER(FIND("ซ.",$A2)),
MID($A2,FIND("ซ.",$A2,1),FIND(" ",$A2,FIND("ซ.",$A2)+3)-FIND("ซ.",$A2)),
"")

E2
=IF(ISNUMBER(FIND("ถ.",$A2)),
MID($A2,FIND("ถ.",$A2,1),
IF(ISNUMBER(FIND("ต.",A2)),FIND("ต.",$A2)-FIND("ถ.",$A2),LEN(A2)-FIND("ถ.",A2)+1)),
"")

F2
=IF(ISERR(FIND("ต.",A2)),"",RIGHT(A2,LEN(A2)-FIND("ต.",A2,1)+1))

คัดลอกสูตรลงมาครับ ลองดูตามไฟล์แนบ

ขอบคุณผู้รู้ทุกท่าน
ผมทำได้แล้วครับ

ประยงค์