Page 1 of 1
การนับจำนวนครั้งของการสแกนนิ้วครับ
Posted: Fri Apr 08, 2022 8:42 am
by Xcelvba
ต้องการนับข้อมูลของการสแกนนิ้วแต่ละรหัส โดยมีเงื่อนไขว่า
1.ถ้าระยะเวลาสแกนห่างกันไม่เกิน 1 นาที จะนับเป็นแค่ 1 ครั้งครับ
ขอบคุณครับ
Re: การนับจำนวนครั้งของการสแกนนิ้วครับ
Posted: Fri Apr 08, 2022 9:45 am
by logic
ลลงแบบนี้ครับ
D1 =IF(ROW(A1)=MATCH(A1,$A$1:$A$3136,0),SUMPRODUCT(--($A$1:$A$3136=$A1),--($C$2:$C$3137-$C$1:$C$3136>=1/24/60))+1,"") คัดลอกสูตรลง
Re: การนับจำนวนครั้งของการสแกนนิ้วครับ
Posted: Fri Apr 08, 2022 1:38 pm
by Xcelvba
ไม่ได้ครับ ขึ้น #VALUE! ครับ
Re: การนับจำนวนครั้งของการสแกนนิ้วครับ
Posted: Fri Apr 08, 2022 2:03 pm
by Xcelvba
logic wrote: Fri Apr 08, 2022 9:45 am
ลลงแบบนี้ครับ
D1 =IF(ROW(A1)=MATCH(A1,$A$1:$A$3136,0),SUMPRODUCT(--($A$1:$A$3136=$A1),--($C$2:$C$3137-$C$1:$C$3136>=1/24/60))+1,"") คัดลอกสูตรลง
เรียนคุณ logic สูตรมีค่า error บางตัวครับ (ตัวอย่าง row ที่53-62) ขอบคุณครับ
Re: การนับจำนวนครั้งของการสแกนนิ้วครับ
Posted: Fri Apr 08, 2022 2:06 pm
by logic
ตอบโพสต์ที่ถาม -- และความหมาย
$C$2:$C$3137-$C$1:$C$3136 คือเอา $C$2:$C$3137 ตั้งแล้วลบออกด้วย $C$1:$C$3136 สังเกตว่ามันเป็นคนละช่วง พูดง่าย ๆ คือเอาเซลล์ล่างลบเซลล์บน
1/24/60 คือ 1 นาที ที่มาคือ 1 วันมี 24 ชม., 1 ชม. มี 60 นาที
อักษร -- ก็คือเครื่องหมาย - เขียนติดกัน 2 อัน อ่านที่อาจารย์อธิบายดีกว่าครับ ~~>
http://snasui.com/viewtopic.php?f=3&t=30&p=135
Re: การนับจำนวนครั้งของการสแกนนิ้วครับ
Posted: Fri Apr 08, 2022 7:24 pm
by logic
Xcelvba wrote: Fri Apr 08, 2022 2:03 pm
สูตรมีค่า error บางตัวครับ (ตัวอย่าง row ที่53-62)
แก้เป็นแบบนี้ดูครับ
D1 =IF(ROW(A1)=MATCH(A1,$A$1:$A$3136,0),MIN(COUNTIFS($A$1:$A$3136,A1),SUMPRODUCT(--($A$1:$A$3136=$A1),--($C$2:$C$3137-$C$1:$C$3136>=1/24/60))+1+(LOOKUP(9.99999999999999E+307,$A$1:$A$3136)=A1)),"")
Re: การนับจำนวนครั้งของการสแกนนิ้วครับ
Posted: Fri Apr 08, 2022 10:19 pm
by Bo_ry
D1
=IF(COUNTIFS(A$1:A1,A1)=1,COUNT(FILTERXML("<x><m>"&TEXTJOIN("</m><m>",,TEXT(C1:INDEX(C1:C20,MATCH(A1,A1:A50)),"h:m"))&"</m></x>","//m[not(preceding::*=.)]")),"")
Re: การนับจำนวนครั้งของการสแกนนิ้วครับ
Posted: Sat Apr 09, 2022 10:25 am
by Xcelvba
logic wrote: Fri Apr 08, 2022 7:24 pm
Xcelvba wrote: Fri Apr 08, 2022 2:03 pm
สูตรมีค่า error บางตัวครับ (ตัวอย่าง row ที่53-62)
แก้เป็นแบบนี้ดูครับ
D1 =IF(ROW(A1)=MATCH(A1,$A$1:$A$3136,0),MIN(COUNTIFS($A$1:$A$3136,A1),SUMPRODUCT(--($A$1:$A$3136=$A1),--($C$2:$C$3137-$C$1:$C$3136>=1/24/60))+1+(LOOKUP(9.99999999999999E+307,$A$1:$A$3136)=A1)),"")
กรณีนี้มี error 65-66 อยู่ครับ
D1 =IF(ROW(A1)=MATCH(A1,$A$1:$A$3136,0),MIN(COUNTIFS($A$1:$A$3136,A1),SUMPRODUCT(--($A$1:$A$3136=$A1),--($C$2:$C$3137-$C$1:$C$3136>=1/24/60))+1+(LOOKUP(9.99999999999999E+307,$A$1:$A$3136)=A1)),"")
Re: การนับจำนวนครั้งของการสแกนนิ้วครับ
Posted: Sat Apr 09, 2022 10:28 am
by Xcelvba
Bo_ry wrote: Fri Apr 08, 2022 10:19 pm
D1
=IF(COUNTIFS(A$1:A1,A1)=1,COUNT(FILTERXML("<x><m>"&TEXTJOIN("</m><m>",,TEXT(C1:INDEX(C1:C20,MATCH(A1,A1:A50)),"h:m"))&"</m></x>","//m[not(preceding::*=.)]")),"")
FilterXML ในไฟล์ที่แนบมาให้ใช้ได้ครับสูตรFilterXML ผมไม่เคยรู้จักครับ วิธีเขียนงงๆ แต่ผมไม่สามารถนำสูตรนี้ไปใช้ใน microsoft 2016 ไม่ได้ครับค่าออกมา 1 ทุกต่าเลยครับ รบกวนด้วยครับ
Re: การนับจำนวนครั้งของการสแกนนิ้วครับ
Posted: Sat Apr 09, 2022 1:44 pm
by Bo_ry
ใส่ Version ให้ตรงกับที่ใช้ด้วยครับ
ver2019.png
=IF(COUNTIFS(A$1:A1,A1)=1,SUM(--(FREQUENCY(--TEXT(C1:INDEX(C1:C20,MATCH(A1,A1:A50)),"h:m"),--TEXT(C1:INDEX(C1:C20,MATCH(A1,A1:A50)),"h:m"))>0)),"")
กด Ctrl+Shift+Enter
Re: การนับจำนวนครั้งของการสแกนนิ้วครับ
Posted: Sat Apr 09, 2022 2:27 pm
by Xcelvba
Bo_ry wrote: Sat Apr 09, 2022 1:44 pm
ใส่ Version ให้ตรงกับที่ใช้ด้วยครับ
ver2019.png
=IF(COUNTIFS(A$1:A1,A1)=1,SUM(--(FREQUENCY(--TEXT(C1:INDEX(C1:C20,MATCH(A1,A1:A50)),"h:m"),--TEXT(C1:INDEX(C1:C20,MATCH(A1,A1:A50)),"h:m"))>0)),"")
กด Ctrl+Shift+Enter
ขอบคุณมากๆครับ เครื่องผม 2019 ครับ แต่พอไปใช้อีกเครื่องในสำนักงานเป็น 2016 ครับ แต่ยังไงตอนนี้ได้แล้วขอบคุณมากๆครับ