Page 1 of 1
อยากได้สูตรตัดคำเพื่อขึ้นแถวใหม่
Posted: Sun Dec 11, 2022 11:15 am
by yangkodza
ตัด.PNG
จากรูปได้ข้อมูลมาเป็นเวลาและตามด้วยข้อมูล
อยากได้สูตรการตัดโดยที่ว่าถ้าเจอเวลาเมื่อไรให้มาตัดขึ้นแถวใหม่เลย โดยเริ่มที่ B6 ครับ
ตัดคำ.xlsx
Re: อยากได้สูตรตัดคำเพื่อขึ้นแถวใหม่
Posted: Sun Dec 11, 2022 12:39 pm
by snasui
ตัวอย่างสูตรตามด้านล่างครับ
- ที่ F6 คีย์สูตรให้แสดงเฉพาะค่าเวลา
=FILTER(TEXT(TRIM(MID(SUBSTITUTE(B3," ",REPT(" ",300)),300*(ROW(1:300)-1)+1,300)),"hh:mm:ss;;;@"),ISNUMBER(--TRIM(MID(SUBSTITUTE(B3," ",REPT(" ",300)),300*(ROW(1:300)-1)+1,300))))
Enter
- ที่ G6 คีย์สูตรเพื่อหาว่าในข้อ 1 อยู่ในตำแหน่งใดของข้อความ
=SEARCH(F6,$B$3)
Enter > Copy ลงด้านล่าง
- ที่ E6 คีย์สูตรเพื่อแสดงคำตอบ
=TRIM(MID($B$3,G6,IF(G7="",50,G7-G6)))
Enter > Copy ลงด้านล่าง
Re: อยากได้สูตรตัดคำเพื่อขึ้นแถวใหม่
Posted: Mon Dec 12, 2022 4:37 pm
by yangkodza
snasui wrote: Sun Dec 11, 2022 12:39 pm
ตัวอย่างสูตรตามด้านล่างครับ
- ที่ F6 คีย์สูตรให้แสดงเฉพาะค่าเวลา
=FILTER(TEXT(TRIM(MID(SUBSTITUTE(B3," ",REPT(" ",300)),300*(ROW(1:300)-1)+1,300)),"hh:mm:ss;;;@"),ISNUMBER(--TRIM(MID(SUBSTITUTE(B3," ",REPT(" ",300)),300*(ROW(1:300)-1)+1,300))))
Enter
- ที่ G6 คีย์สูตรเพื่อหาว่าในข้อ 1 อยู่ในตำแหน่งใดของข้อความ
=SEARCH(F6,$B$3)
Enter > Copy ลงด้านล่าง
- ที่ E6 คีย์สูตรเพื่อแสดงคำตอบ
=TRIM(MID($B$3,G6,IF(G7="",50,G7-G6)))
Enter > Copy ลงด้านล่าง
จากสูตรที่อาจารย์ให้มาทำงานได้ดีเยี่ยมครับ
ขอรบกวนเพิ่มเติมครับ
อยากดึงข้อมูลมาจัดเรียงใหม่ แต่ติดที่เป็นภาษาเกาหลี
ถ้าเป็นแบบรันตัวเลขผมพอทำได้นั่งลองงมมาทั้งวันไม่ผ่านสักทีครับ
s01.PNG
s02.PNG
จัดเรียง.xlsm
Re: อยากได้สูตรตัดคำเพื่อขึ้นแถวใหม่
Posted: Mon Dec 12, 2022 5:19 pm
by snasui
ตัวอย่างสูตรที่เซลล์ L6 ครับ
=IFNA(VLOOKUP(K6,ฐานข้อมูล!$H$2:$I$23,2,0),"")
Enter > Copy ลงด้านล่าง
Re: อยากได้สูตรตัดคำเพื่อขึ้นแถวใหม่
Posted: Mon Dec 12, 2022 6:49 pm
by yangkodza
snasui wrote: Mon Dec 12, 2022 5:19 pm
ตัวอย่างสูตรที่เซลล์ L6 ครับ
=IFNA(VLOOKUP(K6,ฐานข้อมูล!$H$2:$I$23,2,0),"")
Enter > Copy ลงด้านล่าง
สุดยอดครับ สามารถใช้งานได้แล้ว
รบกวนอาจารย์อธิบาย IFNA ให้หน่อยครับ
Re: อยากได้สูตรตัดคำเพื่อขึ้นแถวใหม่
Posted: Mon Dec 12, 2022 6:54 pm
by snasui
จากสูตร
=IFNA(VLOOKUP(K6,ฐานข้อมูล!$H$2:$I$23,2,0),"")
แปลว่า หากผลลัพธ์ของ VLOOKUP(K6,ฐานข้อมูล!$H$2:$I$23,2,0) เป็นค่าผิดพลาด #N/A ให้แสดงเป็นค่าว่าง หากไม่ผิดพลาดก็ให้แสดงผลลัพธ์นั้นครับ