ขอวิธีรวมข้อมูลจาก 2 คอลัมล์ มาเป็นคอลัมล์เดียวต่างชีทกัน

[walayuth]

ขอความช่วยเหลือเพื่อนๆ สมาชิก ครับ
พอดีผมมีข้อมูลรายชื่อบุคคล และตำแหน่งงาน จากตารางใน sheet name ซึ่งเรียงลำดับไว้มีสองด้านซ้าย-ขวา ซึ่งเรียงลำดับไม่เท่ากันครับ
1. ใน sheet P1 นำชื่อบุคคล ใน sheet Name บ้างครั้งมีมากถึง 60 ชื่อ มาใส่เรียงไปตามลำดับ ตั้งแต่ C5 จนถึง C14 พร้อมตำแหน่ง และลำดับที่ ครับ
2. หากยังมีชื่อเหลืออยู่ ให้ใส่ใน sheet P2 โดยเริ่มที่ บรรทัดที่ 2 หรือตั้งแต่ C6 จนถึง C14 ครับ (ยากตรงที่ให้ไปเพิ่มอีกชีทครับ ไม่รู้จะทำยังไงดี)
3. สิ่งที่ทำแล้ว ผมใช้สูตรเติมลำดับที่ ดังนี้ครับ =IF(C5="","",MAX(B2:B4)+1) ก็ได้ผลดีอยู่ครับ
ขอบคุณครับ

[snasui]

หากต้องการให้เพิ่มชีตเองแบบอัตโนมัติจะต้องเขียน VBA เข้ามาจัดการซึ่งจะต้องทำตามกฎการใช้บอร์ดข้อ 5 ด้านบนครับ

แต่หากมีการเพิ่มชีตรองรับเอาไว้ก่อนแล้วก็พอจะใช้สูตรได้

ตัวอย่างสูตรครับ

ที่ชีต Name

1. ที่ W2:Z2 คีย์หัวคอลัมน์เป็น ที่, ชื่อ-นามสกุล, ตำแหน่ง, Sheet ตามลำดับ
2. ที่ W3 คีย์
   =IF(ROWS(W$3:W3)>MAX($B$3:$S$32),"",IFERROR(VLOOKUP(ROWS(W$3:W3),$B$3:$H$32,MATCH(W$2,$B$2:$J$2,0),0),VLOOKUP(ROWS(W$3:W3),$K$3:$Q$32,MATCH(W$2,$B$2:$J$2,0),0)))
   Enter > Copy ไปด้านขวาถึง Y3 > Copy ลงด้านล่างจนเห็นเป็นเซลล์ว่าง
3. ที่ Z3 คีย์
   =IF(W3<>"","Sheet P" &INT((W3-1)/10)+1,"")
   Enter > Copy ลงด้านล่างจนเห็นเป็นเซลล์ว่าง

ที่ Sheet P1

1. ที่ C3 เปลี่ยนข้อความเป็น ชื่อ-นามสกุล (ลบวรรคเดิมทิ้งเพื่อให้เหมือนกับค่าใน X2 ของชีต Name)
2. ที่ C5 คีย์
   =OFFSET(Name!$X$3,MATCH($B$1,Name!$Z$3:$Z$1000,0)-1+ROWS(D$5:D5)-1,MATCH(C$3,Name!$X$2:$Y$2,0)-1)
   Enter > Copy ไป H5 > Copy ลงด้านล่าง

ที่ Sheet P2

1. ที่ C3 เปลี่ยนข้อความเป็น ชื่อ-นามสกุล (ลบวรรคเดิมทิ้งเพื่อให้เหมือนกับค่าใน X2 ของชีต Name)
2. ที่ B6 คีย์
   =IF(C6<>"",MAX('sheet P1'!$B$5:$B$15)+ROWS($B$6:B6),"")
   Enter > Copy ลงด้านล่าง > ปรับสูตรนี้ไปใช้กับชีตอื่น ๆ ที่จะเพิ่มขึ้นมาใหม่
3. ที่ C6 คีย์
   =OFFSET(Name!$X$3,MATCH($B$1,Name!$Z$3:$Z$1000,0)-1+ROWS(C$6:C6)-1,MATCH(C$3,Name!$X$2:$Y$2,0)-1)
   Enter > Copy ไปที่ H6 > Copy ลงด้านล่าง

[walayuth]

ขอบคุณครับ
สูตรที่ได้ตรงกับความต้องการ และนำไปใช้ได้ผลดีมากครับ